use strict;
use warnings;
use Data::Dumper;
use Text::ParseWords;

my $str = 'command1 command2 command3 "command4 --some-arg arg --some-
+other-arg 2" command5';
my @words = shellwords($str);
print Dumper(\@words);
[download]

prints:

$VAR1 = [
          'command1',
          'command2',
          'command3',
          'command4 --some-arg arg --some-other-arg 2',
          'command5'
        ];
[download]

use strict;
use warnings;
my $str = 'command1 command2 command3 "command4 --some-arg arg --some-
+other-arg 2" command5';


for (split m{(\s+|"[^"]*")}, $str) {
    print $_, $/;
}
[download]

That works, but produces a few strings that only contain whitespaces - you can filter them in a separate pass, for example with grep.

The other solution is match your desired output, not the delimiter.

Update: version with filtering:

use strict;
use warnings;
my $str = 'command1 command2 command3 "command4 --some-arg arg --some-
+other-arg 2" command5';

for (split m{(\s+|"[^"]*")}, $str) {
    next if m/^\s/;
    next unless length $_;
    print "<$_>\n";
}
[download]

#!/usr/bin/perl -l
#
use strict;
use warnings;

my $string =
   q{command1 command2 command3 "command4 --some-arg arg --some-other-
+arg 2" command5};

my $inQuotes  = 0;
my $agregator = q{};

my @cmds =
   grep { defined }
   map
   {
       if ( $inQuotes )
       {
           if ( m{"$} )
           {
               s{"}{};
               $agregator .= qq{ $_};
               $inQuotes = 0;
               $agregator;
           }
           else
           {
               $agregator .= qq{ $_};
               undef;
           }
       }
       elsif ( m{^"} )
       {
           s{"}{};
           $inQuotes = 1;
           $agregator = $_;
           undef;
       }
       else
       {
           $_;
       }
   }
   split m{\s+}, $string;

print for @cmds;
[download]

The output.

command1
command2
command3
command4 --some-arg arg --some-other-arg 2
command5
[download]

I hope this is of interest.

Cheers,

JohnGG

Can quoted commands contain quotes? If so, how are they escaped?

$str = 'command1 command2 command3 "command4 --some-arg arg --some-oth
+er-arg 2" command5';
@words = split(/\s/, $str);
$arg_flag = 0;
for $i (0 .. $#words) {
    if ($words[$i] =~ /\"/) {
        if ($arg_flag == 0) { #starting a new command with args
            $arg_flag = 1;
            $words[$i] =~ s/\"//;
            $this_command = $words[$i];
        }
        else { #ending a new command with args
            $words[$i] =~ s/\"//;
            $this_command .= " ".$words[$i];
            push (@commands, $this_command);
            $arg_flag = 0;
        }
    }
    else {
        if ($arg_flag == 0) { #any old command
            push (@commands, $words[$i]);
        }
        else { # an arg in a command being built
            $this_command .= " ".$words[$i];
        }
    }
}
[download]

This looks like a job for Text::xSV. Consider:

use strict;
use warnings;
use Text::xSV;

my $line = 'command1 command2 command3 "command4 --some-arg arg --some
+-other-arg 2" command5';

open my $fh, '<', \$line;

my $parser = Text::xSV->new (fh => $fh, sep => ' ');
my @params = $parser->get_row ();

print join "\n", @params;
[download]

Prints:

command1
command2
command3
command4 --some-arg arg --some-other-arg 2
command5
[download]

Rolled two ways to do it, in case just one page of code might be enlightening.

# Simple command argument extraction:
sub grabArgs {
    my( $cmd )= @_;
    my @args;
    while(  $cmd =~ m{
        (?: ^ | \G )        # Don't skip any characters
        \s*                 # Skip leading whitespace
        (?:
            ([^\s"]+)       # Non-space non-quotes are simple argument
+s, capture
          | (")             # Double-quoted string, capture it as $2
            (               # Capture the inside as $3
                (?:         # Zero or more of the following
                    \\.     # Use \\ and \" to get \ and " inside quot
+es
                  | [^\\"]+ # Not \ nor " means just include it
                )*
            )"
          | ($)             # End of string as $4
        )
        (?! \S )            # Arguments must be space-separated
    }xgc  ) {
        return \@args
            if  defined $4;
        push @args, $2 ? $3 : $1;
        $args[-1] =~ s/\\(.)/$1/g
            if  $2;
    }
    substr( $cmd, pos($cmd), 0, "<ERROR>" );
    die "Invalid command specification near '<ERROR>': $cmd\n";
}

# Pretty much what Text::Shellwords does:
sub parseArgs {
    my( $cmd )= @_;
    my @args;
    while(  $cmd =~ m{
        (?: ^\s* | \G )
        (?:
            ($)                         # $1: End of string
          | (\s+)                       # $2: Whitespace
          | ([^\s\\"']+)                # $3: Nothing special
          | '( [^']* )'                 # $4: 'string'
          | "( (?: \\. | [^\\"]+ )* )"  # $5: "string"
          | \\ (.)                      # $6: \x escape
        )
    }xgc  ) {
        my( $end, $sp, $ns, $sq, $dq, $esc )=
            ( $1, $2, $3, $4, $5, $6 );
        return \@args
            if  defined $end;
        push @args, ''
            if  ! @args;
        if(  $sp  ) {
            push @args, '';
        } elsif(  defined $ns  ) {
            $args[-1] .= $ns;
        } elsif(  defined $sq  ) {
            $args[-1] .= $sq;
        } elsif(  defined $dq  ) {
            $dq =~ s/\\(.)/$1/g;
            $args[-1] .= $dq;
        } elsif(  defined $esc  ) {
            $args[-1] .= $esc;
        } else {
            die "Buggy code";
        }
    }
    substr( $cmd, pos($cmd), 0, "<ERROR>" );
    die "Invalid command specification near '<ERROR>': $cmd\n";
}
[download]

Interestingly, I had to go back to perl 5.005_03 in order to find a Perl that this works on. It appears to tickle bugs in Perl for several 5.8 and 5.6 versions. I might test on 5.10 tomorrow when I have a copy handy again.

Wow... thank you all for your replies.

I cant believe I missed Text::ParseWords though, that is probably the best solution for me. The other examples are food for thought though, especially the solution posted by tye :D

Thanks once again for your help