The docs are fairly self explanatory. The main use is if you have a 'next' statement in your main loop block, but you want something to happen after the 'next'. It just gives you an extra level of flow control in loops (see the docs for where each flow control statement will take you).

Trivial example (but hopefully showing basic use):

while ( my $foo = get_next_foo() ) {
    if ( $foo == 1 ) {
        next;
    }
    do_some_stuff();
} continue {
    # Everything ends up here whether 'next' was hit or not
    do_some_more_stuff();
}
[download]

But sugar of a very sweet kind - it generally saves a level of indentation and avoids obfusification of logic flow.

---

Perl is environmentally friendly - it saves trees

-p uses it to print the output at the end of every loop.

>perl -MO=Deparse -pe1
LINE: while (defined($_ = <ARGV>)) {
    '???';
}
continue {
    print $_;
}
-e syntax OK
[download]

Another example is C-style for loops.
for ($i=0; $i<10; ++$i) { foo }
can be written as
$i=0; while ($i<10) { foo } continue { ++$i }

my $counter = 0;
while ($counter < $limit) {
    my $item = shift @work_queue;
    my $thingy = some_function($item);
    if ($thingy ne 'PARTY') {
        ++$counter;
        next;
    }
    # more code if $thingy ne 'PARTY'
    ++$counter; # thanks ikegami
}
[download]

Here is the same code with the continue block

my $counter = 0;
while ($counter < $limit) {
    my $item = shift @work_queue;
    my $thingy = some_function($item);
    next if $thingy ne 'PARTY';
    # more code if $thingy ne 'PARTY'
}
continue { ++$counter; }
[download]

Here is my general rule of thumb for when to use continue

• You have 1 or more statements that need to be executed every single loop
• You have more than one possible short-circuit condition in the loop

It is a nice way of code re-use. Instead of doing

if ($condition1) {
    # statement 1
    # statement 2
    # statement 3
    next;
}
# more code
if ($condition2) {
    # statement 1
    # statement 2
    # statement 3
    next;
}
[download]

next if $condition1;
# more code
next if $condition2;
[download]

Here is the same code with the continue block

No. Those two snippets are different. The first only does ++$counter when $thingy ne 'PARTY'. The second does ++$counter unconditionally.

my $limit = 3;
my @work_queue = qw( a PARTY b c d);
sub some_function { $_[0] }

...

print(scalar(@work_queue), "\n");
[download]

Prints 1 for the first snippet and 2 for the second.

ikegami,
You are quite correct. The problem was in my code, not my intention. The first should have had a ++$counter at the bottom of the loop. I will update that now.

Cheers - L~R

use strict;
use warnings;

use English qw( -no_match_vars );

RECORD:
while (my $record = <>) {
    # Line number 1 is a header...
    if ($INPUT_LINE_NUMBER == 1) {
        # Per-file preprocessing goes here...

        next RECORD; # Skip to next record...
    }

    # Per-record processing goes here...
}
continue {
    close ARGV if eof;
}
[download]