my ( $id ) = $line =~ m/ID No: (\d+)/;
[download]

Should solve your problem

I see a couple of problems. Look here:

foreach $line (@lines) {
    my $id = $line =~ m/ID No: (\d+)/;
    if ($seen{$id}++){
# ...
[download]

You're going to get 1 for $id all the time because the match is in a scalar context instead of list context.

The other thing is you want to say "if ( ! $seen{$id}++ ) ...". The first time an $id is seen, $seen{$id}++ will be false. Every time after that, it will be true. Since you want it to be true once and false ever after, add the negation.

Here's the part I copied, rewritten:

foreach $line (@lines) {
    my ($id) = $line =~ m/ID No: (\d+)/;
    if ( ! $seen{$id}++){
# ...
[download]

I some other suggestions for you.

First and most important, check the value of open! You try to open your files, but if they fail, you'll never know. Also, it's a generally good idea to use lexical filehandles instead of the global ones you're using.

open my $in_fh, '<:utf8', 'input.txt'
    or die "Can't read 'input.txt': $!";
my @lines = <$in_fh>;
[download]

Second, you're doing everything in memory. If your input is huge, you could run out of memory. Instead of reading every line and then looping over them, consider using a loop that reads a line at a time instead. You'd also want to open your output files at the start and write into them during processing instead of collecting their eventual contents in (memory-based) arrays. Like this:

open my $in_fh, '<:utf8', 'input.txt'
    or die "Can't read 'input.txt': $!";
open my $purge_fh, '>>:utf8', 'purge.txt'
    or die "Can't append to 'purge.txt': $!";
open my $uniq_fh, '>:utf8', 'data.txt'
    or die "Can't write 'data.txt': $!";

my %seen;

while ( my $line = <$in_fh> ) {
    my ($id) = ($line =~ /ID No: (\d+)/);
    if ( ! $seen{ $id }++ ) {
        print $uniq_fh, $line;
        $new_uniq++;
    }
    else {
        print $purge_fh, $line;
    }
}

close $in_fh       or die "Close failed for input: $!";
close $purge_fh    or die "Close failed for purge.txt: $!";
close $uniq_fh     or die "Close failed for data.txt: $!";
[download]

Finally, if you don't already, Use strict and warnings!

Context problem aside, it's usually better^* to use a while loop and process your input line-by-line rather than slurping the entire file into an array.

while( my $line = <FILE> ) {
  ## ...
}
[download]

Your sysadmin and the other users on the box will thank you when input.txt grows to 800M and you don't send the OS thrashing because you've got it all resident in memory.

(*: FSVO "better", of course. Yes it may be fine in this particualr case and this set of inputs will neber eber grow that large fer sure. Really. But you'll be better served by developing a habit of defaulting to line-by-line and only slurping out of conscious choice after looking at the problem.)

#!/usr/local/bin/perl

use strict;
use warnings;

my @lines = <DATA>;
my (@uniq, @purge, %seen);

for my $line (@lines) {
    
    my ($id) = $line =~ m/ID No: (\d+)/;
    
    if (not exists $seen{$id}){
      push @uniq, $line;
      $seen{$id} = undef;
    }
    else { 
      push @purge, $line;
    }
    
}

print qq{uniq\n};
print @uniq;
print qq{purge\n};
print @purge;

__DATA__
lat="37.4192" lng="-122.0574" United States ID No: 1123631397
lat="37.4192" lng="-122.0574" United States ID No: 1123631397
lat="37.4192" lng="-122.0574" United States ID No: 1123631398
lat="37.4192" lng="-122.0574" United States ID No: 1123631399
lat="37.4192" lng="-122.0574" United States ID No: 1123631400
lat="37.4192" lng="-122.0574" United States ID No: 1123631400
[download]

uniq
lat="37.4192" lng="-122.0574" United States ID No: 1123631397
lat="37.4192" lng="-122.0574" United States ID No: 1123631398
lat="37.4192" lng="-122.0574" United States ID No: 1123631399
lat="37.4192" lng="-122.0574" United States ID No: 1123631400
purge
lat="37.4192" lng="-122.0574" United States ID No: 1123631397
lat="37.4192" lng="-122.0574" United States ID No: 1123631400
[download]