in reply to Silencing errors in a php script using perl nd pipes.

The error is probably being sent to STDERR, not STDOUT

Native Bourne shell: 

#!/bin/sh
exec ./home/bevs/bin/email >/dev/null 2>&1

[download]

Bourne shell via Perl: 

#!/usr/bin/perl
exec './home/bevs/bin/email >/dev/null 2>&1';
die;

[download]

Native Perl: 

#!/usr/bin/perl

use strict;
use warnings;

use IPC::Open3 qw( open3 );

open(my $fr_chld, '>', '/dev/null')
   or die;

my $pid = open3(\*STDIN, $fr_chld, $fr_chld, './home/bevs/bin/email');

waitpid($pid, 0)
   or die;

[download]

Replies are listed 'Best First'.
Re^2: Silencing errors in a php script using perl nd pipes.
by Thorney (Initiate) on Jun 20, 2008 at 07:53 UTC
    Thanks very much for your helpful reply! I tried the native bourne shell and it worked. I did try the 2nd option for interests sake and although it didn't output an error it also didn't run my php script on the email. Could you shed any light on why the STDIN is not routed to the php when executed from perl?
[reply]

      I'm guessing that the Perl script's STDOUT and STDERR are getting closed, sending a SIGPIPE to the email server, making it think the child exited. I don't know why it doesn't occur for the first snippet.

      It could be prevented by replacing exec with system if I'm right about the cause. Don't forget to make the call to die conditional or remove it for testing.

      A better system would expand on the third snippet to filter out the expected message while letting anything else through. Turns out it's pretty simple since we don't have to deal with the child's STDOUT, just its STDERR. 

      #!/usr/bin/perl

use strict;
use warnings;

use IPC::Open3 qw( open3 );
use Symbol qw( gensym );

my $pid = open3(
   \*STDIN,
   \*STDOUT,
   my $fr_chld_err = gensym(),
   './home/bevs/bin/email'
);

while (<$fr_chld_err>) {
   next if /Module 'eAccelerator' already loaded/;
   print STDERR $_;
}

waitpid($pid, 0)
   or die;

      [download]
[reply]
[d/l]
[select]
        For that last bit of code. If I remove the . from './home/bevs/bin/email' the php script runs but does not get the email when it reads its STDIN... 
        #!/usr/bin/perl

use strict;
use warnings;

use IPC::Open3 qw( open3 );
use Symbol qw( gensym );

my $pid = open3(
\*STDIN,
\*STDOUT,
my $fr_chld_err = gensym(),
'/home/bevs/bin/email'
);

while (<$fr_chld_err>) {
next if /Module 'eAccelerator' already loaded/;
print STDERR $_;
}

waitpid($pid, 0)
or die;

        [download]
        How do I modify that perl code to pass the standard input on?
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom