See $INPUT_RECORD_SEPARATOR in perlvar for details of what $/ = \$max_length does. See open for a description of the effect of using a scalar reference instead of a filename.

use strict;

my $var = 'x' x 100;
my $max_length = 10;

$/ = \$max_length; # input record separator
$\ = "\n";         # output record separator
open my $FH, "<", \$var or die;
print while <$FH>;
[download]

update: Added link to open

$ perl -le '
> $str = q{x} x 97;
> print for unpack q{(A10)*}, $str;'
xxxxxxxxxx
xxxxxxxxxx
xxxxxxxxxx
xxxxxxxxxx
xxxxxxxxxx
xxxxxxxxxx
xxxxxxxxxx
xxxxxxxxxx
xxxxxxxxxx
xxxxxxx
$
[download]

I hope this is helpful.

Cheers,

JohnGG

I can only add that it's a bad idea to use $&, because it will slow down regex matches in your whole script, and even in modules included from your script.

Use $var =~ s/(\S{$last_length})/$1\n/sg; instead.

it's a bad idea to use $&

Some more background as to why can be found here   (note to the OP — I'm sure you know :)

Wow. Thanks for both of your posts. Unfortunately, I was unaware of the input/output record separators (which I'm ashamed to admit!). Thanks again.

use strict;

local $\ = "\n";
local $_ = 'x' x 1000;
my $pat  = qr/.{1,80}/;

while (/($pat)/g) {
    print $1;
}
[download]

Another one:

my $var = 'x' x 10000;
my $max_length = 100;

my $i = $max_length;
while ($i < length $var) {
    substr($var, $i, 0) = "\n";
    $i += $max_length + 1;
}

print $var, "\n";
[download]

The solutions others have presented are way too complex.

while (my ($block) = $var =~ /(.{1,$max_length})/gs) {
   ...
}
[download]

Note that it's very bad to use $&. It slows down every regexp with no captures in your program.

Update: It a better way of doing the same thing as FunkyMonk's, johngg's, caelifer's, almut's and jwkrahn's code, but our code doesn't do exactly the same thing as yours.

Another way to do it:

my $var = 'x' x 1_000;
my $var_length = length $var;
my $max_length = 100;

for ( my $offset = $var_length - $var_length % $max_length; $offset >=
+ 0; $offset -= $max_length ) {
    substr $var, $offset, 0, "\n";
    }

print "$var\n";
[download]