In any case, I think the better way to fix the original problem is like this:

sub v{
    ord($_[0])-ord("A")+1
}
[download]

UPDATE: I wondered about your comment regarding "weight 1" vs. "weight 0"... are you sure about that? If we are talking about the column labels in a spreadsheet, "A" is col. 1, "Z" is 26, "AA" is 27, etc. That is, each letter "digit" has a "weight" of 1 (if I understand you terminology correctly).

In any case, an even better solution is to let the v() sub split the string and handle the power multiplication:

sub v {
    my (@letters) = split //, $_[0];
    my $sum = 0;
    my $pwr = 1;
    while ( @letters ) {
        my $digit = ord( pop( @letters )) - ord("A") + 1;
        $sum += $digit * $pwr;
        $pwr *= 26;
    }
    return $sum;
}

print v("AB"),"\n";
[download]

Your code works, but there's no reason to create (and pop from) the separate @letters array. Additionally, by doing the multiplication first, we can get rid of the $pwr variable, and get to the much simpler (to my mind, at least),

sub v {
    my $sum = 0;
    for (split //, $_[0]) {
        $sum *= 26;
        $sum += ord($_) - ord("A") + 1;
    }
    return $sum;
}
[download]

You could also factor out the ord("A") + 1 part into a separate variable, but I think it's a little easier to read this way (and the cost of the extra calls to ord is probably negligible).

Looks like you are running afoul of the "special" argument handling that is done by the "print" function,

That's completely wrong. It has nothing to do with print, and all to do with the meaninglessness of the space before opening paren.

$ perl -le'sub f { print("@_"); } f (5) + 4'
5
[download]

Or with warnings:

$ perl -wle'sub f { print("@_"); } f (5) + 4'
Useless use of addition (+) in void context at -e line 1.
5
[download]

In the code in question,

print (v('I')+1)*26 + v('V'), "\n";
[download]

means

print( v('I')+1 )
   * 26
      + v('V'),
"\n";
[download]

Try:

print +(v('I')+1)*26 + v('V'), "\n";
[download]

Enable warnings and you'll get:

[0] Perl> print (v('I')+1)*26 + v('V'), "\n";;
print (...) interpreted as function at (eval 3) line 1, <STDIN> line 1
+.
[download]

Another way :

#!/usr/bin/perl -w
use strict;

print ' AB in 10 base => ', base10('AB'), "\n";
print ' IV in 10 base => ', base10('IV'), "\n";

sub base10{
    my ( %base26, @letters, $sum );
    @letters = reverse split '', shift;
    @base26{ 'A'..'Z' } = 1..26;
    $sum += $base26{ $letters[$_] } * 26**$_ for 0..$#letters;
    return $sum;
}
__END__ 

 Output :
 AB in 10 base => 28
 IV in 10 base => 256
[download]

hth,
PooLpi

Try Math::String.