in reply to representing a tree

If you did any homework, you would have gone to http://search.cpan.org/, typed "tree" in the box and found Tree. 
use Tree;

my @data = (
    [ 1,3 ],
    [ 1,4 ],
    [ 1,5 ],
    [ 3,8 ],
    [ 3,9 ],
    [ 4,11 ],
    [ 4,18 ],
    [ 8,14 ],
    [ 8,15 ],
    [ 5,17 ],
    [ 5,16 ],
    [ 17,21 ],
);

my %nodes;

foreach my $edge ( @data ) {
    my ($parent_id, $child_id) = @$edge;

    my $parent = $nodes{$parent_id} ||= Tree->new( $parent_id );
    my $child = $nodes{$child_id} ||= Tree->new( $child_id );

    $parent->add_child( $child );
}

[download]
Now, you have a tree. Do what you want with it.
My criteria for good software:
  1. Does it work?
  2. Can someone else come in, make a change, and be reasonably certain no bugs were introduced?

Replies are listed 'Best First'.
Re^2: representing a tree
by Anonymous Monk on Jul 03, 2008 at 13:09 UTC
    Heres how to visualize with Tree::Simple::View::ASCII and/or Tree::Visualize (had to switch, only works with Tree::Simple objects): 
    use strict;
use warnings;


my @data = (
    [ 1,3 ],
    [ 1,4 ],
    [ 1,5 ],
    [ 3,8 ],
    [ 3,9 ],
    [ 4,11 ],
    [ 4,18 ],
    [ 8,14 ],
    [ 8,15 ],
    [ 5,17 ],
    [ 5,16 ],
    [ 17,21 ],
);

use Tree::Simple;
my %nodes;
foreach my $edge ( @data ) {
    my ($parent_id, $child_id) = @$edge;

    my $parent = $nodes{$parent_id} ||= Tree::Simple->new( $parent_id 
+);
    my $child = $nodes{$child_id} ||= Tree::Simple->new( $child_id );

    $parent->addChild( $child );
}



use Tree::Visualize;
my $visualize = Tree::Visualize->new( $nodes{1}, 'ASCII', 'TopDown' );
print $visualize->draw(), $/, $/;

use Tree::Simple::View::ASCII;
my $tree_view = Tree::Simple::View::ASCII->new( $nodes{1} );
$tree_view->includeTrunk(1);
print $tree_view->expandAll(), $/, $/;

__END__

                          |                          
                        +---+                        
                        | 1 |                        
                        +---+                        
          ________________|___________________       
          |                  |               |       
        +---+              +---+           +---+     
        | 3 |              | 4 |           | 5 |     
        +---+              +---+           +---+     
       ___|________      ____|____       ____|____   
       |          |      |       |       |       |   
     +---+      +---+ +----+  +----+  +----+  +----+ 
     | 8 |      | 9 | | 11 |  | 18 |  | 17 |  | 16 | 
     +---+      +---+ +----+  +----+  +----+  +----+ 
   ____|____                             |           
   |       |                             |           
+----+  +----+                        +----+         
| 14 |  | 15 |                        | 21 |         
+----+  +----+                        +----+         

1
    |---3
    |       |---8
    |       |       |---14
    |       |       |---15
    |       |---9
    |---4
    |       |---11
    |       |---18
    |---5
            |---17
            |       |---21
            |---16

    [download]
[reply]
[d/l]

In Section Seekers of Perl Wisdom