For instance, with this:

print for
    map { substr $_, 30 }
    sort
    map { sprintf "%-30s%s", (split / /, (split /\|/)[1])[1], $_ }
    <DATA>;

__DATA__
123|Pete Smith|4321|321G4
2134|Mike Malarky|93F821
83|Dave Waylaid|8374W
[download]

Output:

2134|Mike Malarky|93F821
123|Pete Smith|4321|321G4
83|Dave Waylaid|8374W
[download]

The difficult part is that nested split. The inner one, (split /\|/)[1] selects the second field in your data. Then the result is fed to the outer, (split / /, inner)[1], which extracts the second word. That is mapped to a string like this: Malarky                       2134|Mike Malarky|93F821. This string is ASCIIbetically sorted and then, the right part of it is extracted with substr and returned to print. This technique (mapping to a string, sorting and extracting the previously mangled data) is called Guttman-Rosler transform, google for it.

As a side note, I'd like to point out that the first line in your example data appears to have four fields separated with a pipe, while the rest have only three fields.

That's a double-s in Rossler.

According to google:

• "gutman-rosler": 1 match.
• "gutman-rossler": 3 matches.
• "guttman-rosler": 1660 matches.
• "guttman-rossler": 5 matches.

--
David Serrano

@sorted = sort { surname($a) cmp surname($b) } @lines;
[download]

sub surname {
  my $line = shift;
  my @fields = split(/\|/, $line);
  my $fullname = $fields[1]; # extract full name
  my ($first, $last) = split(/ /, $fullname);
  return $last;
}
[download]

There are more clever and efficient ways to write the surname() function, but I just want to demonstrate that you don't have to try to be clever to solve the problem.

This approach extends to any sorting by any property. Just write a function to extract (or compute) that property from the things you are sorting.

If you are concerned about efficiency, have a look at this write-up: A Fresh Look at Efficient Perl Sorting where topics such as the Orcish Maneuver, Schwartzian Transform, and packed-default sort are discussed.

If not, you might take pc88mxers code and change the last split line to:

  my (@name) = split(/ /, $fullname);
  $last= pop @name;
  if ($last=~/(jr|sr)\.?/i) {
    $last= pop @name . ' ' . $last;
  }
[download]

With sort and a regexp:

#!/usr/bin/perl -w
use strict;

my $re = qr/\| \w+ \s+ (\w+) \|/msx;

print sort { 
    my ($aa) = $a =~ $re;
    my ($bb) = $b =~ $re;
    $aa cmp $bb;
    } <DATA>;


__DATA__
123|Pete Smith|4321|321G4
2134|Mike Malarky|93F821
83|Dave Waylaid|8374W

Output :
2134|Mike Malarky|93F821
123|Pete Smith|4321|321G4
83|Dave Waylaid|8374W
[download]

hth,
PooLpi

Sorry for the double post ): Upload very very slow...

PooLpi