in reply to Parse a block of text

You're almost there. I think you probably want something like this:

#!/usr/bin/perl

$infile = "my_file";

open (FILE, $infile) or die "Unable to open $infile: $!";
while(<FILE>) {

  if (/^Info I want/../^Start of Info/) {

    print unless (/^Start of Info/);
  }
}
close (FILE);

[download]

I haven't tested this .. but it should point you in the right direction. Note that a) I tested the open to make sure that the operation succeeded, and b) I didn't read the file into an array.

Alex / talexb / Toronto

"Groklaw is the open-source mentality applied to legal research" ~ Linus Torvalds

Replies are listed 'Best First'.
Re^2: Parse a block of text
by annie06 (Acolyte) on Jul 07, 2008 at 20:40 UTC
    Ok, I'm trying something new as well here and took your suggestions. I want to be able to pass arguments to my script so that it knows what file to open and what to look for in the file:

    for example, you would call it with "my_script file "Info I want" 


    #!/usr/bin/perl

$infile = shift @ARGV;
open (FILE, $infile) or die "Unable to open $infile: $!";

while (<FILE>) {
        foreach (@ARGV) {
                $pattern = $_;
                if ($pattern eq "Info I want") {
                        if (/^Info I want/../^Start of/) {
                                print unless ( /^Start of Info/ );
                        }
                }
        }
}

close (FILE);

    [download]

    But this doesn't return what I need. It actually prints repeated "Info I want" to the screen.
[reply]
[d/l]

      I find that if I add comments as I go, writing code is much easier. Here's some code that works for me:

      #!/usr/bin/perl

use strict;

{
    #  Get filename, starting regex and stopping regex
    #  from the command line.

    my ( $filename, $start, $stop ) = @ARGV;

    #  Check the inputs, open the file.

    die "ERROR: Need to define start and stop arguments."
      unless ( defined($start) && defined($stop) );
    open(INPUT, $filename) or
      die "Unable to open $filename: $!";

    #  Loop through the file, looking for the starting
    #  regexp and skipping lines till then.

    while(<INPUT>) {
      if ( /$start/ ) {

        #  Found the matching line! Print it, and start
        #  looking for the stopping regexp.

        print;
        while(<INPUT>) {

          #  If we found the stopping regexp, drop out
          #  of this loop; otherwise, print a line and
          #  keep going.

          if ( /$stop/ ) { last; } else { print; }
        }
      }
    }
    close(INPUT);
}

      [download]

      I've grabbed all of the arguments from the command line right at the start -- this is far easier than trying to remember what's still left to be read in later.

      The advantage to this code is that it will find multiple occurrences of start/stop in a single file.

      Alex / talexb / Toronto

      "Groklaw is the open-source mentality applied to legal research" ~ Linus Torvalds

[reply]
[d/l]
      I don't quite get what exactly you want to pass in as your patterns since you seem to be hardcoding them anyway...so I'll take a stab in the dark. Also, the ".." and "..." operators return a count of lines matched along with an indicator that tells you if it matched the stop pattern. So: 
      my ($file, $start, $stop) = @ARGV;

$start = qr/^$start/;
$stop = qr/^$stop/;

open(my $fh, "<", $file) or die "Err: $!";
while(<$fh>) {
  if ( my $status = /$start/.../$stop/ ) {
    print unless $status =~ /E/;
  }
}
close $fh;

      [download]
[reply]
[d/l]

In Section Seekers of Perl Wisdom