Perhaps you haven't explained your goal very well, but in any case I'm sure your code as posted does not do what you want. If I understand it correctly:

• There is one directory full of files (so no need to do recursion over subdirectories).
• Each file contains a relatively small number of lines.
• Each line is a "name,value" pair (except the first line, which is just a timestamp).
• You want all the lines in a given file to joined into a single line, by converting line breaks into commas, so each file ends up being just "name,value,name,value,..."
• When that processing is done, you want to load all the file data into an excel spreadsheet, with each original source file being one row.

If that's the basic plan, I wouldn't bother with writing modified versions of every original file. Just output a single stream of data (store it all in a single file), having one line of text for each input file. Something like this:

#!/usr/bin/perl

use strict;  # you really should!

( @ARGV == 1 and -d $ARGV[0] ) or die "Usage: $0 dir_name > out.csv\n"
+;

my $dirname = shift;
opendir( DIR, $dirname ) or die "$dirname: $!";

my @files = grep /.+\.txt$/, readdir DIR;
for my $file ( @files ) {
    my ( $basename ) = ( $file =~ /(.+)\.txt$/ );
    if ( open( F, $file )) {
        my ( $date, @lines ) = <F>;
        chomp $date;
        chomp @lines;
        print join( ",", "sourcefile", $basename, "date", $date, @line
+s ), "\n";
        close F;
    }
    else {
        warn "$file: $!\n";
    }
}
[download]

(I'm assuming you want to keep track of the original file names where all of the output rows come from, as well as all the time-stamps.)

Of course, if it turns out that all the files have the same number of lines, and the same set of names in their various "name,value" pairs, and these names are always in the same order, a better input for excel would have a single line at the top with the names, and then each following line would just have the values in the proper order:

#!/usr/bin/perl

use strict;

( @ARGV == 1 and -d $ARGV[0] ) or die "Usage: $0 dir_name > out.csv\n"
+;

my $dirname = shift;
opendir( DIR, $dirname ) or die "$dirname: $!";

my ( $firstfile, @files ) = grep /.+\.txt$/, readdir DIR;

open( F, $firstfile ) or die "$firstfile: $!";
my ( @names, @values );
my ( $basename ) = ( $firstfile =~ /(.+)\.txt$/ );
my $date = <F>;
while (<F>) {
    chomp;
    my ( $n, $v ) = split /,/, $_, 2;
    push @names, $n;
    push @values, $v;
}
close F;
print join( ",", "sourcefile", "date", @names ), "\n";
print join( ",", $basename, $date, @values ), "\n";

for my $file ( @files ) {
    ( $basename ) = ( $file =~ /(.+)\.txt$/ );
    if ( open( F, $file )) {
        ( $date, @values ) = <F>;
        chomp $date;
        chomp @values;
        s/.+?,// for ( @values );      # delete the "name," parts
        print join( ",", $basename, $date, @values ), "\n";
        close F;
    }
    else {
        warn "$file: $!\n";
    }
}
[download]

(Not tested)

If you're not sure whether all the files have the same set of names in the same order, it would be easy enough to check for that before you try to create the single data stream for importing to excel.