That warning is just a warning, so you can turn it off if you want to.

while ($data_in =~ /<container><a>(.+?)<\/a><b>(.+?)<\/b><\/container>
+(<\?query\?>)??/ig)  {
  {
    no warnings 'uninitialized';
    $data_out = "$2, $1$3 ";
  }
  # further processing
}
[download]

When you turn off a warning that way, it's good to keep that change to the smallest scope possible. In this case, I've scoped it just to that one assignment. See perllexwarn for more.

Alternately, you could check whether $3 is defined:

while ($data_in =~ /<container><a>(.+?)<\/a><b>(.+?)<\/b><\/container>
+(<\?query\?>)??/ig)  {
  if ( defined $3 ) {
    $data_out = "$2, $1$3 ";
    } else {
    $data_out = "$2, $1 ";
    }
  # further processing
}
[download]

Same thing but different:

while ($data_in =~ /<container><a>(.+?)<\/a><b>(.+?)<\/b><\/container>
+(<\?query\?>)??/ig)  {
  $data_out = ( defined $3 ) ? "$2, $1$3 " : "$2, $1 ";
}
[download]

P. S.—Yay for warnings!

It would have been more helpful if you had provided an example of the $data_in string. Is this what you had in mind? ...

use strict;
use warnings;

my $data_in = '<container><a>bbb</a><b>cccc</b></container><?query?>';
my $data_out;
while ($data_in =~ /<container><a>(.+?)<\/a><b>(.+?)<\/b><\/container>
+(<\?query\?>)?/ig)  {
    print "1=$1\n";
    print "2=$2\n";
    print "3=$3\n";
    $data_out = "$2, $1$3 ";
}

__END__
1=bbb
2=cccc
3=<?query?>
[download]

Of course there is probably a much simpler way of achieving this.

Update: Another general note on regexes. You can use alternate delimiters in order to avoid excessive escaping of forward slashes. For example, you can replace // with m{}:

while ($data_in =~ m{<container><a>(.+?)</a><b>(.+?)</b></container>(<
+\?query\?>)?}ig)  {
[download]

The lazy modifier on the regex atom at the very end of the pattern -- the (...)?? -- means that the final capture is never needed to make the overall regex match, so the corresponding capture variable (i.e., $3) will never be defined.

The much simpler way's probably going to involve using a real XML parser (see XML::Twig or XML::Simple) rather than trying to kludge something together with regexen.

I tend to avoid putting ?, +, *, etc on captures. I don't know if the behaviour is even documented, but the behaviour is as follows:

(...)?      Returns undef if it matched 0 items.
((?:...)?)  Returns an empty but defined string if it matched 0 items.
[download]

You can use defined to test in the first case.

my ($data_in, $data_out);

$data_in = q|<container><a>smile!!! </a><b> smile again!! </b></contai
+ner><?query?>|;

while ($data_in =~ /<container><a>(.+?)<\/a><b>(.+?)<\/b><\/container>
+(<\?query\?>)?/ig)  {
  $data_out = "$2, $1$3 ";  #errors here
  ; #further processing here 
  print $data_out;
}
[download]

If you put back the second question mark at the end you will get the error:

Use of uninitialized value $3 in concatenation (.) or string at perlmo
+nks_700143.pl line 8.
[download]

To decipher foreign regexes, I also use YAPE::Regex::Explain (which is also free because it is on CPAN :). Using the OP's original regex (excluding the modifiers, /ig):

use warnings;
use strict;
use YAPE::Regex::Explain;

my $re = '<container><a>(.+?)<\/a><b>(.+?)<\/b><\/container>(<\?query\
+?>)??';
print YAPE::Regex::Explain->new($re)->explain;
[download]

produces this output:

Read more... (4 kB)

While helpful, I still did not grok the ?? usage :(

Thanks for the info InfiniteSilence. RegexCoach is neat.

$_ = q~
one
one two
one two 3
~;

while( /(one) (two)( 3)?/gs ){
    print 'Got 1 ', $1,"\n" if defined $1;
    print 'Got 2 ', $2,"\n" if defined $2;
    print 'Got 3 ', $3,"\n" if defined $3;
    print "----\n";
}
__END__
Got 1 one
Got 2 two
----
Got 1 one
Got 2 two
Got 3  3
----
[download]