#!/usr/bin/perl -w

use strict;

my $var = '';

while(<>){
    $var .= $_;
}

# Do stuff with $var
[download]

If I just want the STDIN (or any file content) in a variable, and don't like to loop, I usually use this idiom:

my $var;
SLURP: { local $/;
    $var= <>;
}
[download]

local-izing $/ in a block undefines it and so no $var gets the whole filecontent sithout looping and reassembling it line by line.

---

s$$([},&%#}/&/]+}%&{})*;#$&&s&&$^X.($'^"%]=\&(|?*{%
+.+=%;.#_}\&"^"-+%*).}%:##%}={~=~:.")&e&&s""`$''`"e

I like Skeeve's solution. It is the best and clearest way to do this in Perl 5.

For the sake of completeness: In Perl 6 the built-in way for this is simply:

$var = slurp \*STDIN;

This can also be done in Perl 5 by using the Perl6::Slurp module.

You can do all of that in one line...

my $var = do { local $/ ; <> };
[download]

---

www.jasonkohles.com
We're not surrounded, we're in a target-rich environment!

However, if you wanted to process each line in turn, you could use a one-liner ... ls -l | perl -ne '{ .... }' to read each line of the ls command, in turn, into $_ or alternatively ... ls -l | perl -ane '{ .... }' will read each line in turn and split it (the line) on whitespace, into @F.

HTH ,

use strict;

use warnings;



print "$_\n" while (<>);
[download]

my @var;
push(@var, $_) while(<>);
[download]

I forgot to mention that you will need to  chomp depending on the situation (e.g. ls adds a "\n" automatically when piped while other commands may not behave in a similar manner).

Just use a piped open, or read perldoc perlipc for the many other ways to do it.

#!/usr/bin/perl

open (LS,"ls |" ) or die $!;
my @files = ();

while(<LS>){
  chomp;
  push @files, $_;
}
print "@files\n";
[download]

I personally believe that quite a full overview of all the possibilities has already been offered to you. But there's a last one missing, that I'm reporting here FYI and for completeness: the implicit open associated with the magic ARGV filehandle is the 2-args one. (Which incidentally I regard as problematic in many senses...) Thus you can pass commands to your script on the command line:

spock:~ [18:59:27]$ perl -0777e 'my $v = <>; print $v' 'ls|'
Desktop
Mail
Mailbox
bin
dead.letter
...
[download]