Take a look at the documentation (using perldoc -f) for the read and seek functions, and for the substr function.

You can use seek to "skip" past parts of a file (let's say 9 bytes), and "read" to read x bytes from your current position in a file.

You could just read the first 9 bytes and throw them away, but seek is better in the general case, so it's not a bad idea to learn about it now.

If your data is in memory, "substr" will let you access any part of it you want, for example the 100 bytes starting at byte 9.

Here's yet another way to do it:

#!/perl/bin/perl
use strict;
use warnings;
use Data::Dumper;

my $str     = '123456789100020003000400050006000';
my $pattern = 'A9(A4)*';
my @values  = unpack($pattern, $str);

print Dumper(\@values);
[download]

Just change the values in the $pattern to suit your needs.

use strict;
use warnings;

my ($line, $line2);
while ($line = <>) {
       chomp($line);
       $line2 = substr($line,9,80);
       print "$line2\n";
}
[download]

I assume, that you want to strip off a fixed size header first and then process a list of records having another fixed size. You can set the input record separator ($/) to a scalar reference holding the record size (see perlvar). Might be slower than (sys)read, though.

#!/usr/bin/perl
use strict;
use Data::Dumper;

my ($n, $m) = (9, 3); # var-names as requested 
my @result;

$/ = \$n;             # record size := 9 characters
$result[0] = <DATA>;  # read one record (size: 9)

$/ = \$m;             # record size := 3 charcters
while (<DATA>) {
        # do something with the next block of 3 chars
        last if length != $m;  # stop at first non m-sized record
        push @result, $_;
}

print Dumper \@result;

__END__
123456789111222333444555666777888999xxxyyyzzzZ
[download]

$VAR1 = [
          '123456789',
          '111',
...
          'zzz'
        ];
[download]