I don't know if I'd like to solve it this way in production but this works. I prefer XML::LibXML for XML stuff but it doesn't do marshalling with Perl data so we bring in XML::Simple which I don't generally recommend but for simple, predictable data it can be nice.

use strict;
use warnings;

use XML::LibXML;
use XML::Simple;

use constant XML_STORAGE => "./whatever.xml";

my %data = ( d20 => int(rand(20) + 1),
             time => time(),
           );

save_data_as_xml(\%data);

# Take a look.
open my $xml_fh, "<", XML_STORAGE or die $!;
print while <$xml_fh>;
close $xml_fh;

sub save_data_as_xml {
    my $data = shift || return;
    my $doc = _get_or_initialize();
    my $new_raw_xml = XML::Simple::XMLout($data);
    my $parser = XML::LibXML->new();
    $parser->recover(1);
    my $new_node = $parser->parse_string($new_raw_xml);
    my $root = $doc->documentElement();
    $root->appendChild( $new_node->documentElement() );
    $root->appendChild( $doc->createTextNode("\n") );
    _save($doc);
}

sub _get_or_initialize {
    my $parser = XML::LibXML->new();
    my $doc = eval { $parser->parse_file(XML_STORAGE) };
    warn $@ if $@;
    return $doc if $doc;
    return $parser->parse_string("<container/>");
}

sub _save {
    my $doc = shift;
    $doc->toFile(XML_STORAGE);
}
[download]