This is a little better (but not tested):

NAME:
foreach my $name ( @name_array ) {
  FILE:
    foreach my $file ( @files ) {
        open my $fh, '<', $file
            or die "Can't read '$file': $!";
        while ( my $line = <$fh> ) {
            chomp $line;
            if ( lc $line eq lc $name ) {
                print OUTPUTFILE "$line\n";
                next FILE;
            }
        }
    }
}
[download]

Note a few things:

• Once a name is found in a file, I break out of the loop and go to the next file using next FILE (made possible by the label on that loop).
• I check to see whether open failed, and I die if so.
• I use chomp to take the line ending off the lines. That leaves just the name with no newline.
• I compare names using eq and lc. That makes it case-insensitive, but it won't match partial names to full names (i.e., "Fred" won't match "Frederick").
• I do not read the whole file at once. I read it a line at a time and conserve memory.

The way you're trying to do it with regular expressions means that you'll end up matching partial names with full names (i.e., "Fred" will match "Frederick" and "Liam" will match "William"). If that's what you want, fine. You can say $line =~ /\Q$wanted_name/ and get that (see also quotemeta).

If you want each name to be found only once regardless of how many files it's in, you can change my "next FILE" to "next NAME" to skip over other files once the name is found.

Update: I also Use strict and warnings

You don't seem to have problem 1 in your code. As for problem 2, if a name matches in several places, all occurrences will be printed. If you want uniqueness use an hash. The following example illustrates the differences:

use strict;
use warnings;

my @names = ('joe', 'mary', 'francis');
my @lines = <DATA>;

my %lines_matched;
my @all_found;

foreach my $name (@names) {
    my $wanted = $name;

    foreach my $line (@lines) {
        if ($line =~ m/\b$wanted\b/i) {
            push @all_found, $line;
            $lines_matched{$line} = 1;
        }
    }
}

print foreach @all_found;
print "\nNow the uniques:\n";
print foreach keys %lines_matched;

__DATA__
Joe is lazy
Robin Wood
Mary Poppins
Francis Bacon
Ruppert
Joe married Mary
[download]

outputs

Joe is lazy
Joe married Mary
Mary Poppins
Joe married Mary
Francis Bacon

Now the uniques:
Francis Bacon
Joe married Mary
Joe is lazy
Mary Poppins
[download]

update. added \b after reading kyle's comment.

my @name_array = qw(fred joe john frank );
for my $file(@file) {
    open(FILE, "<", $file) 
        or die("can't open file $file.\n");
    while (my $line = <FILE>) {
        my $match = grep { $line =~ /$_/i } @name_array; 
        print OUT $line if ( $match );
    }
}
[download]

my %unique;
if ( $have_a_line_to_print ) {
    $unique{$have_a_line_to_print} = 1;
}
#
# much later
#
for( sort keys %unique ) {
    print;
}
[download]

• use strict;
• use warnings;
• Use the 3 argument variant of open
• Test the status returned from the call to open

• Attempt to slurp the file in one, but have forgotten local undef $/;.
• Fail to open OUTPUTFILE

If you're reading into an array, you always get the whole file regardless of the value of $/. Also, local alone is enough to undef $/.