So how about some code? Try something. See how well it works (or not). Then post it along with an explanation of what you really want it to do and how your expectations are not being met.

And see How (Not) to Ask a Question for tips on what folks here expect to see when you ask for help.

I understand what you're saying, and I hope it does not seem like I am asking anyone to write me code. I am just trying to figure out where to start, and was asking some help there. I read the CSV file into an array and read it line-by-line, but not sure how to count occurence of the numbers, nor how to break them into sets based on the headers.

You should almost never "read the file into an array". In general for large files that leads to poor performance.

In the particular case of CSV files you should not process them line by line! CSV generally allows line breaks within fields so a row of data may span more than one line. Not a common case I grant you, but the Text::xSV module correctly handles that case along with the more common case of a line is a row.

To solve any programming problem it helps to start with a high level sketch of how things are going to go so even coding up what you have described and using comments to indicate where work needs to be done would be considered as a good starting point.

---

Perl reduces RSI - it saves typing

CSV of course immediately triggers "use a csv module", so that part is easy: Text::xSV or one of the CSV modules.

"most common occurence" should trigger "hash for uniqueness". Consider:

my @items = qw(foo poot bar foo baz poot foo);
my %counts;

++$counts{$_} for @items;

print "$_: $counts{$_}\n" for sort keys %counts;
[download]

The trick then is to figure out how to process groups coming at you a row at a time. There are a bundle of ways of doing that. A simple way is to perform the processing for the previous group each time you see a new group header (unless there was no previous group):

use strict;

my @rowTypes = (1, 2, 3, 3, 3, 1, 2, 3, 3, 1, 2, 1, 3);
my $count;

for my $rowType (@rowTypes) {
    if ($rowType == 1) {
        # New group
        next unless defined $count; # No processing for first or empty
+ group
        print "$count ";
        $count = 0; # Reset count. Set to undef to skip empty group
        next;
    }
    
    ++$count if $rowType == 3;
}

print "$count " if defined $count; # Need to process the last group
[download]

> I don't have any code to really post, because I can't think of how to start this one...

<hint type="broad"> Try looping over your input file, collecting the data in a hash, and analyzing it.</hint>

If you then post the code here, and explain exactly where you're getting stuck (this assumes that all your questions haven't yet been answered - although effort is usually the thing that resolves questions), you'll find a number of capable people willing to help.

Please note that "help" here on PerlMonks is not defined as "we'll do it for you". It is, usually, defined as "you do it, and we'll assist as necessary."

-- 
Human history becomes more and more a race between education and catastrophe. -- HG Wells

OK, so you need to identify the start and end of each group, and count the number of times within each group that each number occurs, and print out the most popular ?

What do you want to do if several are equally popular ?

You want to read the file, line by line. Unless the CSV is guaranteed simple, you should consider using CSV module to parse it for you. Anything involving recognising strings, probably you want to use a hash for. (With numbers you could use an array, but if the number range is bit or sparse, use a hash anyway.) Then unpeel the hash to extract the collected data.

So... something along the lines of:

  use strict ; use warnings ;
  use List::Util qw(max) ;

  open my $STUFF, "<", "stuff.csv"   or die "$!" ;

  my %number_ids = () ;

  while (my $line = <$STUFF>) {
    $line =~ s/\s+\z// ;
    $line =~ s/\A\s+// ;
    my @csv = split(/\s*\,\s*/, $line) ;

    if    (defined($csv[2]) && ($csv[2] =~ m/^\d+$/)) {
      $number_ids{$csv[2]}++ ;
    }
    elsif (defined($csv[4]) && ($csv[4] =~ m/^group\:/i)) {
      show_most_popular(\%number_ids) ;
      print $line, "\n" ;
      %number_ids = () ;
    }
    else {
      # OK, so what do we do with peculiar lines ?
    } ;
  } ;

  show_most_popular(\%number_ids) ;

  sub show_most_popular {
    my ($r_ids) = @_ ;

    return if !%$r_ids ;

    my $max = max(values %$r_ids) ;
    my @popular = () ;
    while (my ($id, $count) = each %$r_ids) {
      if ($count == $max) { push @popular, $id ; } ;
    } ;

    print join(',', sort @popular), "\n" ;
  } ;
[download]

Various bits of Perl magic:

• $line =~ s/\s+\z// will remove any trailing whitespace, including any form of newline known to me. This is more general than chomp IMHO.
• $line =~ s/\A\s+// smacks any leading whitespace.
• my @csv = split(/\s*\,\s*/, $line) smacks any whitespace around the separators.
• $number_ids{$csv[2]}++ -- if the entry for the id already exists, increment it. Otherwise, create the entry, undefined, and increment, which gives 1.
• worth being clear that although the field looks numeric, it's a string at this point. That means that ids '123' and '0000123' would be different.
• show_most_popular(\%number_ids) passes the hash by reference, to be tidy.
• <code>return if !%$r_ids<code> -- returns if the hash referred to by $r_ids is empty (OK, so that's obvious)

OK, so I was at a loose end.

Update: I should also have noted that the code is assuming that the 'Group:' lines include the apparently floating ',,,,'. Also, that when knocking out this kind of thing -- scan a file to recognise and pick out stuff to process -- it is important to trap stuff that hasn't been recognised; the odd's are that you'll find bugs either in the code or in your understanding of the data.