in reply to Toplevel Window References in Perl Tk

You might get some clues if you add "use warnings;" to your script.

To be honest, I can't figure out what you are trying to do? :-) I've never seen code like this: 

if(! Exists($obj->{mw})) 
    {    
        $obj = bless {mw => $wind->Toplevel()};
        $obj->{mw}->title("Child Window");

[download]
So I'm wondering what you are trying to do?

Anyways, to get the reference to a Toplevel, just save it somewhere. 

my %toplevels;
$toplevel{$count}{'toplevel'} = $wind->Toplevel();

[download]
You seem to be trying to track windows, by setting their Titles, but I may not understand your code. You should save them in hashes or arrays.

Anyways, add warnings to your script, fix the warnings problem, and straighten out your hashes. Sorry, this code is too convoluted for me to understand.

I'm not really a human, but I play one on earth Remember How Lucky You Are

Replies are listed 'Best First'.
Re^2: Toplevel Window References in Perl Tk
by lara26 (Initiate) on Sep 11, 2008 at 08:38 UTC
    Hi, Thanks for your response. I am able to get the reference of the Toplevel windows but i am unable to get the reference of the widgets that are created in the Toplevel window. {Ex I want to get the reference of the Frame that i have created in Toplevel1} I am unable to get that reference. Any suggestions on the same
[reply]
      Hi, here is the basic idea. There is some error checking left out, like removing a key from the hash if you destroy a toplevel, but it shows the idea. This is a very straight forward method, but there are others, like looping thru all the pack children of the toplevel, then finding the Frame hash.... but stick with the straight forward until you get more experience. 
      #!/usr/bin/perl
use warnings;
use strict;
use Tk;

my $count = 0;
my %tls;   #hash to store the toplevels

my $mw = MainWindow->new;
$mw->title( "MainWindow" );

my $spawn_button = $mw->Button( -text => "Toplevel", 
                -command => \&do_Toplevel )->pack();

my $report_button = $mw->Button( -text => "Report", 
                -command => \&report )->pack();


MainLoop;

sub do_Toplevel {
    
   my $num = $count++;
   $tls{$num}{'tl'} = $mw->Toplevel();
        
   $tls{$num}{'tl'}->protocol('WM_DELETE_WINDOW' => sub {
         print "do nothing here\n"; #prevents destruction of $tl
                            #by WM control
     });
        
  $tls{$num}{'tl'}->title( "Toplevel $count" );

  $tls{$num}{'frame'}= $tls{$num}{'tl'}->Frame()
              ->pack(-expand=>1, -fill=>'both');

  $tls{$num}{'label'} = $tls{$num}{'frame'}->Label(-text=>$count)
                        ->pack(-expand=>1, -fill=>'x');

  $tls{$num}{'tl'}->Button(
    -text    => "Close",
    -command => sub { $tls{$num}{'tl'}->withdraw; 
              }
        )->pack;
}

sub report {
 
  foreach my $num (keys %tls){
        
         print "toplevel $num has frame ", $tls{$num}{'frame'},"\n";
  
       }
}

      [download]
      I'm not really a human, but I play one on earth Remember How Lucky You Are
[reply]
[d/l]

In Section Seekers of Perl Wisdom