Yes, that's completely incorrect.

First, "g" doesn't do that at all. It means (more or less) "all instances".

# Check for a match
if (/pat/) {
   ...
}

# Find all matches
while (/pat/g) {
   ...
}
[download]

Second, that's not how regexps match at all.

print( 'abc' =~ /b/      ?1:0,"\n");  # 1
print( 'abc' =~ /^b\z/   ?1:0,"\n");  # 0
print( 'abc' =~ /^abc\z/ ?1:0,"\n");  # 1

print( 'a2b3c' =~ /(\d)/     ?$1:0,"\n");  # 2
print( 'a2b3c' =~ /^.*(\d)/  ?$1:0,"\n");  # 3
print( 'a2b3c' =~ /^.*?(\d)/ ?$1:0,"\n");  # 2
[download]

References:

• perlop (m//, s/// and qr//)
• perlre
• perlrequick
• perlretut

Yes, that is misunderstanding the role of the g modifier. Simplistically /g means "match as many times as you can". In a list context that means the regex will return all the matches it finds. Consider:

my @matches = '1 foo 22 bar 3' =~ /\d+/g;
print "@matches";
[download]

Prints:

1 22 3
[download]

In scalar context however it returns true while there is a "next" match. To see what was matched we now have to capture the bit we are interested in:

while (my $match = '1 foo 22 bar 3' =~ /(\d+)/g) {
    print "$1 ";
}
[download]

which generates the same output as above. Your code is rather like this last version except that you have "unwound" the loop.

To get the behaviour you expected without the /g you need to "anchor" the match at the start of the string using ^:

my @matches = '1 foo 22 bar 3' =~ /^\d+/g;
print "@matches";
[download]

which prints '1'. For further regex reading see perlretut, perlre and perlreref.