use strict;
use warnings;

open my $inFH, q{<}, \ <<'EOD' or die qq{open: << HEREDOC: $!\n};
1,XYZ,desc,PDF
2,YGH,desc,KMN
1,XYZ,desc,QFZ
EOD

my %ids;
while ( <$inFH> )
{
    chomp;
    my ( $key, $value ) = m{^(.*,)(.*)$};
    push @{ $ids{ $key } }, $value;
}

print qq{$_@{ [ join q{,}, @{ $ids{ $_ } } ] }\n}
   for keys %ids;

close $inFH or die qq{close: << HEREDOC: $!\n};
[download]

The results.

1,XYZ,desc,PDF,QFZ
2,YGH,desc,KMN
[download]

Note that hashes are not ordered so if you want to impose a particular order in your output file you will need to sort the keys in some fashion. This exercise is left to the reader.

I hope this is useful.

Cheers,

JohnGG

Update: Corrected typo, s/nor/not/

use strict;
use warnings;

my %AB;
while (<DATA>) {
     chomp;
     my ($id, $name, $desc, $app) = split /\s*,\s*/;
     $AB{$id}{app}      .= ",$app";
     $AB{$id}{name_desc} = "$name, $desc";
}

for (keys %AB) { $AB{$_}{app} =~ s/^,// } # remove leading comma

for my $id (sort keys %AB) {
    print "$id, $AB{$id}{name_desc}, $AB{$id}{app} \n";
}

__DATA__
1, XYZ, desc, PDF
1, XYZ, desc, QFZ
2, YGH, desc, LMN
[download]

Update: On second thought, this version is cleaner because it does not unnecessarily inject that comma:

This prints:

1, XYZ, desc, PDF,QFZ
2, YGH, desc, LMN
[download]

I do know what I've been told about using the "my" before the various scalars, arrays, hashes, etc. The person that I'm writting these for doesn't like when I use those.

Thank you so much for your reply. The first one printed out some results but I don't seem to be getting it to group the ID's together. Maybe I did something wrong when I was importing the different code?? I'm not sure. I so much appreciate your looking at this for me. This is the code I just tried to use:

#!/usr/bin/perl -w

open (IN, "c:/work/Abnova_Grouping/Abnova_App_and_Key.txt");
open(OUT, ">c:/work/Abnova_Grouping/Abnova_App_and_Key_Sorted.txt");

     my%AB;
while(<IN>){ 
     chomp;
         my($id, $prod_num, $app, $note)=split /\s^,\s^/;
     $AB{$id}{app} .= ",$app";
     $AB{$id}{prod_num}="$prod_num, $note";
    
}

for (keys %AB) { $AB{$_}{app}=~s/^,//}

for my $id (sort keys %AB){
    print OUT "$id, $AB{$id}{prod_num}, $AB{$id}{app} \n";
    }
    
close IN;
close OUT;
[download]

Thank you again for your help!!

I'm not sure what you're going to do with the output, though. Using the same delimiter for multiple items does make things more ... entertaining. What you have to start with is something you can probably feed into DBD::CSV and do queries against. What you're transforming it into will only be parsable by custom code (possibly based on Text::CSV_XS).

If you want to reduce duplication yet still maintain some orthogonality, you could normalise your file into two files: one with ID/name/description, the second with ID and product. ID's would still be listed multiple times, but the name and description wouldn't be.

This would also lend itself to feeding into a more full-featured data store (such as Sqlite, mySQL, postgreSQL, or even DB2 or Oracle) at a later date for more advanced handling. (See my latest database-oriented project. The output is basically pure SQL calls against nearly normalised data.)

# ------------------------------------------------------------
%Struct = ();
open (IN, "Abnova_Product_List.txt");
while(<IN>)
{ 
    chomp($_);
   ($Key,$Name,$Desc,$OneApp) = split(/\t/,$_);
   
   if (! exists $Struct{$Key})
   {
      $refArray = [$Name,$Desc,$OneApp];
      $Struct{$Key} = $refArray;
   }
   else
   {
      $refArray =  $Struct{$Key};
      push (@$refArray,$OneApp);
   }
}
close(IN);
open (OUT, ">Abnova_Products.txt");
foreach $Key (keys %Struct)
{
  $refArray = $Struct{$Key};  
  print OUT "K=$Key\t".join("\t",@$refArray)."\n";
}
close (OUT);
[download]

I tried your code, but I got the following error: Use of uninitialized value in concatenation (.) or string at 710425.pl line 8, <IN> line 1.

It is possible to have some sample data file so I can try the code again.

Thank you.