I'd probably use a hash of hashes for this (see perldsc). The top level keys would be your "text1" and "text2". Second level keys would be "text-a", "text-b", etc. The values would just be 1 or something. When you're done, loop over the keys of the top level, and in the loop, get the keys of the second level. It may help to know what's in perlreftut and perlref.

If you get stuck, post the code you have, and we can help further.

The code that I was trying to modify was...
my %hash;
while(<DATA>){
chomp;
my @line = split /\t/;
my $first = shift @line;
push( @{$hash{$first}}, @line );
}
foreach( sort keys %hash ){
print OUT "$_\t".join("\t", sort @{$hash{$_}})."\n";
}

my %hash;
while(<DATA>){
    chomp;
    my @line = split /\t/;
    my $first = shift @line;
    $hash{$first}{$_}++ for @line;
}
foreach( sort keys %hash ){
    print STDOUT "$_\t".join("\t", sort keys %{$hash{$_}})."\n";
}
__DATA__
text1   text-a  text-a  text-b  text-a
text1   text-c
text2   text-a  text-b
text2   text-b  text-d
[download]

All I changed was the push line and the print line. Output:

text1   text-a  text-b  text-c
text2   text-a  text-b  text-d
[download]

my @top_level;
my %seen;
my @cache;

while (<>) {
    chomp;
    my ($key, @thingies) = split /\t/;
    unless ($seen{$key}) {
        push @top_level, $key;
        $seen{$key} = {};
    }
    push @{$cache{$key}}, grep {!$seen{$key}{$_}++} @thingies;
}
foreach my $key (@top_level) {
    say join "\t", $key, @{$cache{$key}};
}
[download]

Thanks Guys for your excellent code!
Freddie