What you are missing is use strict;.

I stronlgy suggest you read: Coping with scoping.

As far as your problem goes: I'm guessing you want: if ($key =~ /Hox/) { instead of if ($Gene_Symbol =~ /Hox/) {.

There is a pile of stuff that can be tidied up there. First off, always use strictures (use strict; use warnings;).

Use chomp instead of chop.

Use the three parameter version of open and check the result. Use lexical file handles:

open my $inFile, '<', "MOUSE_TF1.txt" or die "Failed to open MOUSE_TF1
+.txt: $!";
[download]

Instead of using "parallel" data structures that have to be handled piecemeal, group common data using a hash:

use warnings;
use strict;

open my $inFile, '<', "MOUSE_TF1.txt" or die "Failed to open MOUSE_TF1
+.txt: $!";

my %families;
my @fields = qw(chr start end symbol strand);

while (<$inFile>) {
    my $line = $_;
    chomp ($line);

    my @Gene_Info = split "\t", $line;
    my $id = shift @Gene_Info;

    @{$families{$id}}{@fields} = @Gene_Info;
}
close $inFile;

# select Gene Symbols belonging to "Hox" family and print
foreach my $key (keys %families) {
    if ($key =~ /Hox/) {
        print join ("\t", $key, @{$families{$key}}{@fields}), "\n";
    }
}
[download]

untested

Instead of using "parallel" data structures that have to be handled piecemeal, group common data using a hash

But that uses more memory. Which can be significant if you have a lot of data.

#!/usr/bin/perl

use 5.010;

use strict;
use warnings;

use Devel::Size qw [total_size];

my $size = 250_000;

my @fields = qw [chr start end symbol strand];
my %families;
my @structs = \my (%chr, %start, %end, %symbol, %strand);

foreach my $key (1 .. $size) {
    $families{$key}{$_} = undef for @fields;  
    $$_{$key} = undef for @structs; 
}

my $s1 = total_size \%families; 
my $s2 = 0; 
   $s2 += total_size $_ for @structs;

printf "Big hash: %d Mb\n", $s1 / (1024 * 1024);
printf "More hashes: %d Mb\n", $s2 / (1024 * 1024);
printf "Savings: %.0f%%\n", 100 * ($s1 - $s2) / $s1;

__END__
Big hash: 71 Mb
More hashes: 61 Mb
Savings: 14%
[download]

Grouping the data in a hash causes you to have 1250001 hashes, instead of just 5. Which carries a 10 Mb penalty.

Interesting. Using Perl 5.8.8 rather than 5.10 makes the same saving for 'Big hash':

Big hash: 61 Mb
More hashes: 52 Mb
Savings: 16%
[download]

so should we all use 5.8.8 rather than 5.10? Actually 14 (or 16) % is sufficiently small to be irrelevant for most purposes. Clarity of code is the more important factor (not that I'm claiming that my code is any clearer mind you), especially for a first cut - optimize later if you need to.

---

Perl reduces RSI - it saves typing

In the line if ($Gene_Symbol =~ /Hox/) {, $Gene_Symbol still has the value it had in the last round of the while loop; it is in no way affected by the foreach loop. What you probably want is to match against the value that you stored in the %symbols hash for every key. That is,

  if ($symbols{$key} =~ /Hox/) {
[download]

use strict;
use warnings;

open INPUT,"<MOUSE_TF1.txt" or die "can not open MOUSE_TF1.txt: $!";
open OUTPUT,">HOX_GENE_TF.txt" or die "can not open HOX_GENE_TF.txt: $
+!";   
print OUTPUT "MOUSE TRANSCRIPTION FACTORS IN THE HOX GENE FAMILY\n\n\n
+";
print OUTPUT "ENSEMBL GENE ID \tSYMBOL \tCHR\tSTART\t\tEND\t\tSTRAND\n
+";
while (<INPUT>){
  chomp;
  my ($id, $cname, $start, $end, $strand, $sym) = split /\t/;
  # select Gene Symbols belonging to "Hox" family and print
  if ($Sym =~ /^Hox/) { print join("\t", $id, $sym, $cname, $start, $e
+nd, $strand), "\n" }
}
close INPUT;
close OUTPUT;
[download]

If you are willing to preserve the column order from the input, this simplifies even further to:

use strict;
use warnings;

open INPUT,"<MOUSE_TF1.txt" or die "can not open MOUSE_TF1.txt: $!";
open OUTPUT,">HOX_GENE_TF.txt" or die "can not open HOX_GENE_TF.txt: $
+!";   
print OUTPUT "MOUSE TRANSCRIPTION FACTORS IN THE HOX GENE FAMILY\n\n\n
+";
print OUTPUT "ENSEMBL GENE ID \tCHR\tSTART\t\tEND\t\tSTRAND\tSYMBOL\n"
+;
while (<INPUT>){
  chomp;
  my @items = split /\t/;
  # select Gene Symbols belonging to "Hox" family and print
  if ($items[5] =~ /^Hox/) { print "$_\n" }
}
close INPUT;
close OUTPUT;
[download]

if ($Gene_Symbol =~ /Hox/) {
[download]

if ($symbols{$key} =~ /^Hox/) {
[download]

    $ grep ^Hox MOUSE_TF1.txt > HOX_GENE_TF.txt
[download]