Re^2: How to instrust Perl to load the right modules based on architecture?

Aside from mispelling "lib", the order of execution is totally wrong. Your code is equivalent to:

BEGIN {
    require Config;
    Config::->import();
    require lib;
    lib::->import('./lib64/perl5/5.8.5/x86_64-linux-thread-multi');
    require lib;
    lib::->import('./lib64/perl5/site_perl/5.8.5/x86_64-linux-thread-m
+ulti');
    require lib;
    lib::->import('./lib64/perl5/5.8.5/i386-thread-multi');
    require lib;
    lib::->import('./lib64/perl5/site_perl/5.8.5/i386-thread-multi');
    if ($Config{archname64}) {
        # empty
    } else {
        # empty
}
[download]

Note that all four directories are added to @INC unconditionally because use statements are executed as soon as they are compiled. Fix:

BEGIN {
    use Config;
    require lib;

    if ($Config{archname64}) {
        lib->import(qw(
            ./lib64/perl5/5.8.5/x86_64-linux-thread-multi
            ./lib64/perl5/site_perl/5.8.5/x86_64-linux-thread-multi
        ));
    } else {
        lib->import(qw(
            ./lib64/perl5/5.8.5/i386-thread-multi
            ./lib64/perl5/site_perl/5.8.5/i386-thread-multi
        ));
    }
}
[download]

Update: Markup changes.

Comment on Re^2: How to instrust Perl to load the right modules based on architecture? Select or Download Code

Replies are listed 'Best First'.
Re^3: How to instrust Perl to load the right modules based on architecture? by sunshine_august (Scribe) on Oct 06, 2008 at 06:09 UTC
Thanks, it works now. But I still a little confused with the "use lib" and the BEGIN block, which one is executed first, the "use lib" or the BEGIN block? And, I find that the BEGIN block's location makes difference. If I put it ahead of the script like this: use strict; use warnings; use FindBin; use lib "$FindBin::Bin/lib"; use lib "$FindBin::Bin/lib/perl5/site_perl/5.8.5"; BEGIN { use Config; require lib; print "archname:$Config{archname}\n"; if ($Config{archname} =~ /^x86_64/) { print "x86_64\n"; lib->import( "$FindBin::Bin/lib64/perl5/5.8.5/x86_64-linux-thread-multi", "$FindBin::Bin/lib64/perl5/site_perl/5.8.5/x86_64-linux-thread +-multi"); } else { print "i386\n"; lib->import( "$FindBin::Bin/lib/perl5/5.8.5/i386-linux-thread-multi", "$FindBin::Bin/lib/perl5/site_perl/5.8.5/i386-linux-thread-mul +ti"); } } use utf8; use threads; use Carp; use IO::Socket::SSL; use IO::Select; use Log::Log4perl; [download] My script works well, but if I put the BEGIN block at the tail like this: use strict; use warnings; use FindBin; use lib "$FindBin::Bin/lib"; use lib "$FindBin::Bin/lib/perl5/site_perl/5.8.5"; use utf8; use threads; use Carp; use IO::Socket::SSL; use IO::Select; use Log::Log4perl; BEGIN { use Config; require lib; print "archname:$Config{archname}\n"; if ($Config{archname} =~ /^x86_64/) { print "x86_64\n"; lib->import( "$FindBin::Bin/lib64/perl5/5.8.5/x86_64-linux-thread-multi", "$FindBin::Bin/lib64/perl5/site_perl/5.8.5/x86_64-linux-thread +-multi"); } else { print "i386\n"; lib->import( "$FindBin::Bin/lib/perl5/5.8.5/i386-linux-thread-multi", "$FindBin::Bin/lib/perl5/site_perl/5.8.5/i386-linux-thread-mul +ti"); } } [download] It throw the error "Can't locate Net/SSLeay.pm in @INC", and I can't find the right path in @INC. Where the BEGIN block exactly should be? The very beginning of the script, even before "use strict; use warnning"? I also change the $Config{archname64} to $Config{archname} and, use $Config{archname} =~ /^x86_64/ to decide whether It is a x86_64 host. Because I find that $Config{archname64} is empty(although existed) in both i386 and x86_64 Perl.	[reply] [d/l] [select]
Re^4: How to instrust Perl to load the right modules based on architecture? by ikegami (Patriarch) on Oct 06, 2008 at 07:15 UTC
But I still a little confused with the "use lib" and the BEGIN block, which one is executed first, the "use lib" or the BEGIN block? `BEGIN` blocks are executed as soon as they are fully compiled, i.e. when the `}` is reached. `use` statements are executed as soon as they are fully compiled, i.e. when the `;` is reached. In other words, whichever ends first gets executed first. Where the BEGIN block exactly should be? The very beginning of the script, even before "use strict; use warnning"? Before `use`ing any modules that require the changed `@INC`. If it finds `utf8`, `strict`, `warnings` with the default `@INC`, I'd load those first. That's just my personal preference.	[reply] [d/l] [select]