Replace "keys %hoa" with the list of specific names.

By the way, $input = $_ is wrong.
$input = $_ is an assignment.
$input == $_ is a numerical comparison.
$input eq $_ is a string comparison.
See perlop.

#!/usr/bin/perl
use strict;

my %hoa = (
"arraya" => [ "dd1", "dd2", "dd3", "dd4" ],
"arrayb" => [ "gg1", "gg2", "gg3", "gg4" ],
"arrayc" => [ "cc1", "cc2", "cc3", "cc4" ]
);


my $input = <STDIN>;
 chomp $input;

 
if ((exists $hoa{$input}) and $input eq (@{$hoa{arraya}}))
{
print (@{$hoa{arraya}});
}
[download]

moritz explained, so what follows is a solution. Basically, comparing a single value against an array makes so sense. By using grep, the value can be compared against every element of the array.

#!/usr/bin/perl

use strict;
use warnings;

my %hoa = (
   arraya => [qw( dd1 dd2 dd3 dd4 )],
   arrayb => [qw( gg1 gg2 gg3 gg4 )],
   arrayc => [qw( cc1 cc2 cc3 cc4 )],
);

chomp( my $array_name = <STDIN> );   # e.g. arraya 
chomp( my $to_find    = <STDIN> );   # e.g. dd2

if (  exists( $hoa{$array_name} )
   && grep { $_ eq $to_find } @{$hoa{$array_name}}
) {
   print( @{$hoa{$array_name}}, "\n" );
}
[download]

Though looking up a hash will often be better than doing a linear search along a list. For example:

#!/usr/bin/perl

use strict;
use warnings;

my %hoh = (
  flasha => { dd1 => 1, dd2 => 2, dd3 => 3, dd4 => 4 },
  flashb => { gg1 => 1, gg2 => 2, gg3 => 3, gg4 => 4 },
  flashc => { cc1 => 1, cc2 => 2, cc3 => 3, cc4 => 4 },
);

for ([qw(flasha dd4)], [qw(glashz gg2)], [qw(flashc zz)], [qw(flashc c
+c1)]) {
  my ($array_name, $to_find) = @$_ ;
  if (exists $hoh{$array_name}->{$to_find}) {
    print( "$array_name contains $to_find\n" );
  }
}
[download]

noting that exists stops looking, without complaint, if $hoh{$array_name} doesn't exist.

If the list is a trivial length, then List::Util::first at least stops looking when it gets a match.

I don't know what you need to do having discovered the match... the above allows you to map "array name" and "to_find" to anything you like -- the numbers above are for illustration, only !

If you're only interested in existence, then

   flasha => { map { ($_, undef) } qw(dd1 dd2 dd3 dd4) },
[download]

will serve.

I think you answered my question as I was writing it! Awesome thanks.

To satisfy the first condition (exists $hoa{$input}) $input has to be any of arraya, arrayb, arrayc. To satisfy the second condition, $input has to be equal to whatever @{$hoa{arraya}} stringifies to, which is probably 4 (because it's an array in scalar context, giving you the number of items in the array).

Since no string is both equal to array$something and to 4 at once, you'll never get output from that script.

I see. Would it be possible then to change the second condition in order to make sure that;
$input has to be equal to arraya or @{$hoa{arraya}}?
After that I will also need to iterate over each value of arraya... Err another thing I was thinking about was that
there might be a different way to grab a specific array that exists inside a hash. Lets say I have 50
arrays inside my hash and I want to do something to each value of a specific array based on <STDIN>. I dont want
to right out 50 elsif statements... please help!