#!/usr/bin/perl
use warnings;
use strict;

my %myData= (
    'Method1' => {
        'Name' => 'ABC',
        'File' => 'Beta.dat',
        'Category' => 'Methods',
        'Params' => 'ARGV'
    },
    'Method2' => {
        'Name' => 'MNO',
        'File' => 'Alpha.dat',
        'Category' => 'Functions',
        'Params' => 'ARGV'
    },
    'Method3' => {
        'Name' => 'ABA',
        'File' => 'Beta.dat',
        'Category' => 'Methods',
        'Params' => 'ARGV'
    },
    'Method4' => {
        'Name' => 'MNZ',
        'File' => 'Alpha.dat',
        'Category' => 'Functions',
        'Params' => 'ARGV'
    }
    );

my @unsorted = keys %myData;

my @sorted = sort 
  { $myData{$a}{'Category'} cmp $myData{$b}{'Category'} or
    $myData{$a}{'File'} cmp $myData{$b}{'File'} or 
    $myData{$a}{'Name'} cmp $myData{$b}{'Name'} } @unsorted;


print join(' ', @sorted),"\n";

#prints
Method2 Method4 Method3 Method1
[download]

This works because cmp gives back 0 on equality. Which means that the 'or' doesn't short circuit and tests the next comparision.

I dropped the 'reverse' from the sort and exchanged $a and $b of the cmp instead.

Always use strictures (use strict; use warnings; - see The strictures, according to Seuss). Use meaningful variable names. In particular, never be tempted to use names like 'tempN'. $temp1 should be $currCat, $temp2 should be $currFile and temp3 could be $currMethod.

You use %myData and %mydata. They should probably be the same thing. Strictures would have alerted you immediately. Correcting that and using your sample data prints:

Functions
Alpha.dat
MNO
Methods
Beta.dat
ABC
[download]

See other replies for a better solution to your problem.

  my %hoh = (Method1 => { ... },
             Method2 => { ... },
             ...);

  foreach my $key (sort {$hoh{$a}{Category} cmp $hoh{$b}{Category} or
                         $hoh{$a}{File}     cmp $hoh{$b}{File}     or
                         $hoh{$a}{Name}     cmp $hoh{$b}{Name}} 
                   keys %hoh) {
      print Dump $hoh{$key}
  }
[download]

Hey Java Fan,
My apologies for the complicated code. As much as i'd like to simplify it, I have not been able to get the functionality i want.
As mentioned earlier, my goal is to just sort the hash for print purposes. I do not care what order it is otherwise. The data i have is a collection of methods of different categories stored in different files.
I wish to print them in ascending order of Category then ascending order of files that belong to that category followed by ascending order of Name of methods in each of those files. ie.

Functions
    Alpha.dat
       ...
       MNO
       ...
    ...
....
Methods
    Beta.dat
       ABC
       ...
    ...
...
[download]

As explained earlier, I can do it, but it takes too much time to do so and I wanted to know if i can speed it up.
I hope this explains what I wish to achieve.
Bugz

In which way doesn't my code do what you want?

 #--snip -- Hash declaration omitted --
#--  Schwartzian Transform Sort --
my @sorted=  map{ 
                $_->[3] 
            } sort{ 
                $a->[0] cmp $b->[0]  
                || 
                $a->[1] cmp $b->[1]
                || 
                $a->[2] cmp $b->[2] 
            } map{ 
                [ @{ $myData{$_} }{qw| Category File Name | },$_] 
            } keys %myData;
   print join (", ",@sorted), "\n"; 

#Prints: Method2, Method4, Method3, Method1
[download]