Re: Substitution inside tags, as 1 line

...as 1 line.

How about 44? :-) This uses a parser to get the data you need and a template to put it all back together again.

Over the top? Possibly. I have a particular aversion to having any HTML in my code, even more so in a regex. It almost always ends in tears. This way I have no HTML in the code at all (the source and the template would normally be in separate files). YMMV.

#!/usr/local/bin/perl

use strict;
use warnings;

use HTML::TokeParser::Simple;
use HTML::Template;

my $p = HTML::TokeParser::Simple->new(\get_html());
my ($in_pre, $pre);
while (my $t = $p->get_token){
    $in_pre++, next if $t->is_start_tag(q{pre});
    next unless $in_pre;
    last if $t->is_end_tag(q{pre});
    $pre .= $t->as_is;
}
my @lines = grep{/\S/} split /\n/, $pre;

my $tmpl = HTML::Template->new(scalarref => \get_tmpl());
my @loop = map{{line => $_}} @lines;
$tmpl->param(loop => \@loop);
print $tmpl->output;

sub get_html{
    return <<HTML;
<html>
<pre>
line 1
line 2
line 3
</pre>
</html>
HTML
}

sub get_tmpl{
    return <<TMPL
<html>
<TMPL_LOOP loop>
<p><TMPL_VAR line></p>
</TMPL_LOOP>
</html>
TMPL
}
[download]

<html>

<p>line 1</p>

<p>line 2</p>

<p>line 3</p>

</html>
[download]

Comment on Re: Substitution inside tags, as 1 line Select or Download Code

Replies are listed 'Best First'.
Re^2: Substitution inside tags, as 1 line by tel2 (Pilgrim) on Nov 05, 2008 at 07:23 UTC
Hi wfsp. I finally made time to test your solution, and thanks very much for your input. Nice work! While I don't think my situation warrants using your code, I may well use it in future if I have a more complex problem to deal with, and I appreciate the time you took to demonstrate this method. BTW: The single line processing requirement I gave was about the way I wanted to treat the htmlfile, rather than the number of lines of code. Thanks again.	[reply]

Replies are listed 'Best First'.

Re^2: Substitution inside tags, as 1 line
by tel2 (Pilgrim) on Nov 05, 2008 at 07:23 UTC

I finally made time to test your solution, and thanks very much for your input. Nice work! While I don't think my situation warrants using your code, I may well use it in future if I have a more complex problem to deal with, and I appreciate the time you took to demonstrate this method.

BTW: The single line processing requirement I gave was about the way I wanted to treat the htmlfile, rather than the number of lines of code.

Thanks again.

[reply]