Your first call to readdir goes into "my $dir" and then gets discarded by the next call in the condition of the while loop.

opendir my $Tdir, "/path/to/anywhere"
    or die "Can't opendir '/path/to/anywhere': $!";
my $dir;
while($dir = readdir($Tdir)){
    print "$dir\n";
}
closedir $Tdir;
[download]

hmm, i've been using this with no errors for almost a decade. Odd that it never was a problem before. but your are right. This code works:

opendir Tdir, "/var/www/campbell/campbell.edu/www/content/2/";
while(my $d = readdir(Tdir)){
print "<li>$d\n";
}close Tdir;
[download]

jtrue

It was a problem before! That's why you never saw the '.' directory; you discarded it. Obviously, in the past you got the files from readdir ordered, with the '.' and '..' directories in front and that's not the case on RH (and shouldn't be depended on).

Paul

Sounds like your new version of redhat has a subtle change to the readdir(2) operation (or maybe you changed the filesystem type you were on??). I am pretty sure that, in general, readdir simply returns the entries in the order that they appear in the file. You never used to see "." because it should always be the first entry in the directory file, and your script was discarding it. Now, for some reason, the first entry returned by readdir was not ".", but a file you cared about. Since opendir/readdir say nothing about entry ordering, "it's not a bug -- it's a feature":)

You still have two bugs and two instances of poor programming.

• close doesn't work on directory handles. You need closedir .

• You'll stop iterating prematurely if you have a file named 0 (zero). You need to check if the result of readdir is defined. Check if it's false isn't good enough.

• Why are you using a global variable for the directory handle?

• It's so easy to check opendir for errors, it's a very likely candidate for errors. Add a check!

my $Tdir_qfn = "/var/www/campbell/campbell.edu/www/content/2/";
opendir(my $Tdir_dh, $Tdir_qfn)
   or die("Can't read dir \"$Tdir_qfn\": $!\n");

while (defined( my $f = readdir($Tdir_dh) )) {
   print "<li>$f\n";
}

closedir($Tdir_dh);
[download]

Did you check which file is missing, e.g. compare ls -la with your programs output? Is it always the same?

I checked your program here (SuSE 10.2, perl 5.8.8) and was surprised to see that there was a delta of one file too! Problem was counting the output of ls -la | wc -l vs. perl yourprogram.pl | wc -l. The delta was caused by this line: total 84! Maybe...?

Update: This works here:

#!/usr/bin/perl
use strict;

my %ls = map { chomp; $_ => 2 } qx{/bin/ls -1};

opendir(DIR,".") or die "cannot readdir here - $!";
$ls{$_}++ foreach  readdir(DIR);

my @where = ("","readir only", "ls only", "both");
foreach (sort keys %ls) {
  printf("%12s: %s\n", $where[ $ls{$_} ], $_);
}

__END__
readir only: .
readir only: ..
       both: file1.pl
       both: file2.pl
       both: path
[download]

$somepath = '/path/to/anywhere';
opendir(DIR, $somepath) or warn "Can't open that directory : $!\n";
@files = ('', readdir(DIR));
foreach $file (@files) {
  push @keepers, "\"$file\"\n" if ($file ne '' and $file ne '..' and
$file ne '.');
}
closedir(DIR);
print $#keepers + 1 . " files encountered :\n" . join("",@keepers);
[download]