Switch to a string comparison instead of a numerical comparison and it'll work. Didn't you notice all the "Argument isn't numeric in numeric ne (!=)" warnings?

my @allcompanies = qw(
   Acme
   Google
   Yahoo
);

my $to_remove = 'Acme';

my @selectcompanies = grep { $_ ne $to_remove } @allcompanies;

print(join(', ', @selectcompanies), "\n");  # Google, Yahoo
[download]

use strict;
use warnings;
use Data::Dumper;

my $co = 'b';
my @allcompanies = qw(a b c d);
print Dumper(\@allcompanies);
@allcompanies = grep { $_ ne $co } @allcompanies;
print Dumper(\@allcompanies);

__END__

$VAR1 = [
          'a',
          'b',
          'c',
          'd'
        ];
$VAR1 = [
          'a',
          'c',
          'd'
        ];
[download]

@allcompanies = grep { not $_ eq $co } @allcompanies
[download]

While not $_ eq $co isn't incorrect, I rather write $_ ne $co.

Notice if there are duplicates, this will whack all of them.

That's easily solved:

my $i = 0;
@allcompanies = grep {$_ ne $co or $i++} @allcompanies;
[download]

While not $_ eq $co isn't incorrect, I rather write $_ ne $co.

I like yours better too.

About duplicates: I assume whacking dups is actually what was intended based on the problem description, but I thought it would be worthwhile to mention that side-effect.

works like a charm. guess that is why I should always have use warnings on, right? thanks again-

@allcompanies = grep {!/^$co$/} @allcompanies;
[download]

Using the match operator to compare strings exactly is overkill, and you got it wrong. I don't think many companies use regexp patterns for names.

@allcompanies = grep {!/^\Q$co\E$/} @allcompanies;
[download]