You have a second problem.

$day = "sunday";
$userId= "mary";

BEGIN  {
push (@INC, "./dir_$day");
}

...
[download]

is processed as follows:

• $day = "sunday"; is compiled.
• $userId= "mary"; is compiled.
• BEGIN { push (@INC, "./dir_$day"); } is compiled.
• BEGIN { push (@INC, "./dir_$day"); } is executed.
• ... is compiled.
• $day = "sunday"; is executed
• $userId= "mary"; is executed
• ... is executed

As you can see, $day is only given a value long after the BEGIN block uses them. It always amazes me that people are willing to come to PerlMonks to find a problem with their code when use warnings; would have told them. The two most useful tools:

use strict;
use warnings;
[download]

Solution:

my $userId= "mary";

BEGIN  {
   my $day = "sunday";
   push (@INC, "./dir_$day");
}

...
[download]

All together:

#!/usr/bin/perl

use strict;
use warnings;

BEGIN {
   my $day    = "sunday";
   my $userId = "mary";

   push (@INC, "./dir_$day");

   eval "use module_$userId qw( ); 1" or die $@;
   *diary = \%diary::diary;
}
[download]

It doesn't make much sense to specify %diary on the use line do the alias via an assignment. That means the %diary on the use line is being ignored. You can fix that by using Exporter. Then you'd replace the last two lines with:

   eval "use module_$userId qw( %diary ); 1" or die $@;
[download]

By the way, please don't include line numbers in posted code. We are quite able to count to fifteen. All it does is make it very hard to cut and paste.