my @eles  = ( 1, 5, 3 );
my @prios = ( 5, 2, 1 );

my @idxes =  sort { $prios[$a] <=> $prios[$b] } 0..$#eles;

@eles  = @eles [ @idxes ];
@prios = @prios[ @idxes ];

print(join(', ', @eles), "\n");
[download]

Create an array of indices sorted by @b and then use it to reorder both arrays:

@a = (1,5,3);;
@b = (5,2,1);;
@sortedIndices = sort{ $b[ $a ] <=> $b[ $b ] } 0 .. $#b;;

@a = @a[ @sortedIndices ];;
@b = @b[ @sortedIndices ];;

print "@a\n@b";;
3 5 1
1 2 5
[download]

Consider to choose another data representation.
You can tie numbers and priorities in some ways

# as array of arrays
my @data_aoa = (
  [1, 5],                # [number, priority]
  [5, 2],
  [3, 1]
); 

# or more verbose as array of hashes
my @data_aoh = (
  {number => 1, pri => 5 },
  {number => 5, pri => 2 },
  {number => 3, pri => 1 }
);

# now sort by priority

my @sorted_aoa = sort { $a->[1] <=> $b->[1] } @data_aoa;

my @sorted_aoh = sort { $a->{pri} <=> $b->{pri} } @data_aoh;
[download]

Do your array indices matter to you? Probably not. Perl lets you ignore them.

What matters is that each item in @b is the PRIORITY OF the item in @a. To remember this, use a hash.

my %priority_of;
@priority_of{@a} = @b;
my @a_sorted_by_priority
    = sort { $priority_of{$a} <=> $priority_of{$b} } @a;
[download]

Efficiency experts may shudder at the hash lookups inside the sort block, but I say clarity first. Perl code can express what you care about. At a later stage it can be optimized.

Speaking of clarity, the names @a and @b don't really express what you are thinking about. I have replaced @b with %priority_of. What kind of thing is listed in @a?