Season with error handling to taste:

#! perl -slw
use strict;
use IO::Socket;

$|++;

sub recv_timeout {
    my( $socket, $timeout ) = @_;
    
    ## Set up a select vector for the scoket
    my $vin = ''; vec( $vin, fileno( $socket ), 1 ) = 1;
    
    ## Wait for $timeout seconds
    if( select( $vin, undef, undef, $timeout ) ) {
        
        ## Go fetch
        my $portaddr = recv( $socket, my($input), 1500, 0)
            or return; ## Read failed

        ## Who from
        my( $port, $addr ) = sockaddr_in( $portaddr );
        $addr = join '.', unpack 'C4', $addr;
        
        return ( $addr, $port, $input );
    }
    ## Timeout
    return;
}

my $server = IO::Socket::INET->new(
    LocalHost => 'localhost:54321',
    Proto => 'udp',
    Reuse => 1.
) or die $^E;

## Set socket non-blocking
my $true = 1; ioctl( $server, 0x8004667e, \$true); 

while( 1 ) {
    if( my( $addr, $port, $input ) = recv_timeout( $server, 5 ) ) {
        print "\nGot '$input' from '$addr:$port'";
    }
    printf '.';
}
[download]

BrowserUk: thanks for your code but I am unclear as that how I can integrate it within my code... Any clues or guidance?

Any clues or guidance?

As I can't see your code, it's kind of hard. In general, wherever you would recv, call my recv_timeout( ) sub instead.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

"Too many [] have been sedated by an oppressive environment of political correctness and risk aversion."

I haven't done it myself, but maybe you can use select or IO::Select to wait for an incoming packet with a timeout. I don't know if it works for UDP sockets though.