Do you want (1) to read only the lines

jdk
jhfk
[download]

Or (2) should your output also include the start and stop reading tokens, like

process jkdgf
jdk
jhfk
end process
[download]

For (1), the following code does the trick.

use strict;
use warnings;

my $print_flag = 0;
while (<DATA>) {
    if (/end process/) {
        last;
    }
    elsif (/process/) {
        $print_flag = 1;
    }
    else {
        print if $print_flag;
    }
}

__DATA__
ghklg
process jkdgf
jdk
jhfk
end process
[download]

Output:

C:\Perl\src>perl 721648.pl
jdk
jhfk
[download]

Hi Richb, Thanks for ur reply.. But i still have a small problem.. as this is able to check for only one loop and not repeated loop.. eg

 
process lkhls
ksjhfk
end process
process kfhls
kfh
end process
[download]

i want output as

ksjhfk
kfh
[download]

Thanks....

flipflop operator to the rescue:

perl -lne 'print if /^process/ .. /^end process/
  and not /^process/ and not /^end process/'
process lkhls
ksjhfk
end process
process kfhls
kfh
end process
[download]

apparently does what you want:

ksjhfk
kfh
[download]

[]s, HTH, Massa (κς,πμ,πλ)

You might also consider the flip-flop operator (see Flipin good, or a total flop?)

In your problem, the code would look something like:

while(<WORDLIST>)
{
    if( /^process/ .. /end process/ )
    {
        #recognize and skip first delimiter
        next if /^process/;
        #recognize and skip end delimiter
        next if /end process/;
        # do something with the middle.
        print;
    }
}
[download]

This does have the advantage that it restarts if you hit another line starting with process. Obviously, you can also do something special with the start and end points.

Of course, if you don't need to know when the data starts and stops, you could just do

while(<WORDLIST>)
{
    next if /^process/ or /^end process/;
    print;
}
[download]

while(<WORDLIST>)
{
    next if /^process/ or /^end process/;
    print;
}
[download]

You could consider combining the two matches into one (I would also use unless but I know that's not to everyone's taste).

while( <WORDLIST> )
{
    print unless m{^(?:end\s)?process};
}
[download]

I hope this is of interest.

Cheers,

JohnGG

I probably would combine them (and use unless), but I was keeping it simple for early morning.<grin/>

G. Wade

local $_;
while(<WORDLIST>)
{   last if /process/;
}
while(<WORDLIST>)
{   print;
    last if /end process/;
}
[download]

Hi Markov, Thanks for ur reply.. But i still have a small problem.. as this is able to check for only one loop and not repeated loop.. eg

 
process lkhls
ksjhfk
end process
process kfhls
kfh
end process
[download]

i want output as

ksjhfk
kfh
[download]

Thanks....

Do this if what only what you require is the bit between:

print grep { !/process/  } <>;
[download]

perl <script>.pl <input>.txt
[download]


prints


ksjhfk
kfh
[download]


You could also put this in an array

my @process = grep { !/process/  } <>;
[download]

However this would just be each element for each line. If you wanted them grouped you need something more complex using assertions ( if you do it the inefficent way like i have )
John,

UPDATE: This would group them

{
    local undef $/;
    print split /process \s \w+ (.+?) end \s process/xms, <>;
}
[download]


P.S. Don't actually use these methods of doing it, There just other ways to do it.

my $printing;
while(<WORDLIST>) {
   $printing = 0 if (/^end process/);
   print if ($printing);
   $printing = 1 if (/^process/);
}
[download]

Given your example, unless I misunderstand this should be all you need:

while (<WORDLIST>){
    next if /process/;
    print;
}
[download]