my ($filter_re) = map qr/$_/,
                  join '|',
                  map quotemeta,
                  @filters;

for my $phrase (@phrases) {
   $phrase =~ s/$filter_re//ig;
}
[download]

use Regexp::List qw( );

my $filter_re = Regexp::List
                ->new(modifiers => 'i')
                ->list2re(@filters);

for my $phrase (@phrases) {
   $phrase =~ s/$filter_re//g;
}
[download]

The second should be faster is Perls earlier than 5.10.

Update: Made case-insensitive.

Or did you mean

@mainarray contains "In", "to", "the", wild"

Use grep to filter out array elements.

my %filters = map { lc($_) => 1 } @filters;
my @words = grep !$filters{lc($_)}, @words;
[download]

First of all, try super search. There are lots of nodes out there that ask similar questions. Here is the one, for example that I picked off the top of the list.

Now, I'm sure there are better ways of doing this, but the simple implementation just iterates over both arrays and uses splice.

#! /usr/bin/perl

use strict;
use warnings;
use Data::Dumper;

my @array=qw(In to the wild);
my @filterarray=qw(the);
print Dumper @array;
for(my $i=0;defined $array[$i];$i++){
    my $word=$array[$i];
    foreach my $filter (@filterarray){
        if($filter eq $word){
            splice (@array,$i,1);
        }
    }
}
print Dumper @array;
exit 0;
[download]

In case you're not familiar, Data::Dumper is your friend when it comes to quickly printing out output, especially arrays and hashes. 'qw' means separate whatever's inside the brackets and put them in single quotes (no variable interpolation). So qw(Into the wild) -> ('Into', 'the', 'wild'). And always use strict and use warnings.

hope that helps
why_bird

Ikegami's solution to build up a big filter-regex might be faster, but maybe this one is just simpler

@main=("In to the wild" ,"The catcher in the rye") ;
@filters=("the","in");


for $filter (@filters) { 
     s/\Q$filter\E//ig for @main; 
}


print "@main"; #  to  wild  catcher   rye
[download]

\Q and \E are for quoting possible regexcode in @filter. If you want to get rid of whitespaces or dupplicate replacements and so on just improve the regex, it's up to you!

Thanks to all. I tried to use the suggested solutions, but it seems I have not well specified what I meant: the words included in @filter must match when they're not embedded in other words... Using the code above, when @filter meets a phrase in @main that contains, for example, "Ethernet", it strips out "the" and it returns "Ernet" , and that's not what I meant... Sorry if I was unclear.. I tried anyway to do :

for $filter (@filters) { 
     s/\Q\b$filter\b\E//ig for @main; 
}
[download]

adding the \b bound delimiter, but still it doesn't work. How should I improve the regex to obtain what I need? Thank you again.

\b should be OK, but your escaping it within \Q and \E !!!

Cheers LanX

- - - - - Which song???

> .. Sorry if I was unclear.. I

no prob, a certain unclearity was obvious and the reason why I gave you a simple and expandable approach to start with. 8 )

So, did you already think about the whitespaces left? ; )

You may want to consider \s* instead of \b.

When speed is a matter think about tuning the final solution like ikegami showed you!

Cheers LanX

- - - - - Which song???

Is this homework?