Probably you'll get better advice but this was a fun and straightforward little problem so-

package MyRanger;
use strict;
use Carp;

sub new {
    my $caller = shift;
    my $self = bless {}, $caller;
    $self->{_range_string} = shift || croak "You must provide a range"
+;
    for my $entry ( split /\s*,\s*/, $self->{_range_string} )
    {
        if ( $entry =~ /\A\d+\z/ )
        {
            push @{$self->{_raw_range}}, $entry;
        }
        elsif ( $entry =~ /\A(\d+)-(\d+)\z/ )
        {
            carp "Range '$entry' is impossible, skipping"
                and next if $1 > $2;
            $entry =~ s/-/../;
            push @{$self->{_raw_range}}, eval $entry;
        }
        else
        {
            croak "Illegal range entry '$entry' given";
        }
    }
    @{$self->{_range}} = sort { $a <=> $b } keys %{ { map {$_ => 1} @{
+$self->{_raw_range}} } };
    @{$self->{_range}} || croak "No range was parseable in ", $self->{
+_range_string};
    $self->{_pos} = 0;
    $self;
}

sub next {
    my $self = shift;
    $self->{_range}->[$self->{_pos}++];
}

1;

my @range_strings = (
                     "1, 3, 5-7",
                     "1-5, 2, 4, 10, 100",
                     "1-3, 2-5",
                     "12-10",
                     );

for my $string ( @range_strings )
{
    print "MyRanger->new with '$string'\n";
    my $ranger = MyRanger->new($string);

    while ( my $item = $ranger->next() ) {
        print "\tNext item is: $item\n";
    }
}
[download]

Extra stuff like-

sub size {
    my $self = shift;
    scalar @{$self->{_range}};
}
[download]

...d'oh, left up to you. :)