my %to_find = map { $_ => 1 } keys %{ $KLARF_REGEXP{$KLARF_VERSION} };

while ( <FILE> ){
    for my $field ( keys %to_find ) {
        next if !/$KLARF_REGEXP{$KLARF_VERSION}{$field}/;

        if ( @- > 1 ) {
            $summary->{$field} = $1;
            LogMsg( "Found $field $summary->{$field}" );
        } else {
            LogMsg( "Found $field" );
        }

        delete $to_find{$field};
    }
}

die if keys %to_find;
[download]

You'll get a slow down since you now have to check every pattern for every line instead of just one.

An alternative implementation is to load the entire file into memory if it fits.

my $file; { local $/; $file = <FILE>; }

for my $field ( keys %{ $KLARF_REGEXP{$KLARF_VERSION} ) {
    die if !/$KLARF_REGEXP{$KLARF_VERSION}{$field}/;

    if ( @- > 1 ) {
        $summary->{$field} = $1;
        LogMsg( "Found $field $summary->{$field}" );
    } else {
        LogMsg( "Found $field" );
    }
}
[download]

The other way is to stitch the regexes together, so that you run a single regex per line, and then sort out which field(s) you've found when you get a match. Along the lines of:

use strict ;
use warnings ;

my %KLARF_REGEXP = (
  '1.X'   =>  {
                    'LOTID'     => qr/LotID "(.+)";/i,
                    'DEVICEID'  => qr/DeviceID "(\w+)";/i,
                    'STEPID'    => qr/StepID "(.+)";/i,
                    'SLOTID'    => qr/Slot (\d+);/i,
                    'DEFECTS'   => qr/DefectList/i,
                    'RESULT_T'  => qr/ResultTimestamp (.+);/i,
                    'WAFERID'   => qr/WaferID "(.+)";/i,
                    'SETUPID'   => qr/SetupID (.+);/i,
                    'OMARK'     => qr/OrientationMarkLocation (.+);/i,
                    'DIEPITCH'  => qr/DiePitch (.+);/i,
                    'CENTER'    => qr/SampleCenterLocation (.+);/i,
              },
  '1.8'   =>  {
                    'LOTID'     => qr/LotRecord "(.+)"/i,
                    'DEVICEID'  => qr/DeviceID 1 \{"(\w+)"\}/i,
                    'STEPID'    => qr/StepID 1 \{"(.+)"\}/i,
                    'SLOTID'    => qr/Field SlotNumber 1 \{(\d+)\}/i,
                    'DEFECTS'   => qr/DefectList/i,
                    'WAFERID'   => qr/WaferRecord "(.+)"/i,
                    'RESULT_T'  => qr/Field ResultTimestamp \d \{(.+)\
+}/i,
                    'SETUPID'   => qr/Field RecipeID 3 \{(.+)\}/i,
                    'OMARK'     => qr/Field OrientationMarkLocation 1 
+\{(.+)\}/i,
                    'DIEPITCH'  => qr/Field DiePitch \d \{(.+)\}/i,
                    'CENTER'    => qr/Field SampleCenterLocation \d \{
+(.+)\}/i,
              },
);

my $vers = '1.8' ;

my $r_items = $KLARF_REGEXP{$vers} ;

my $r  = join('|', values(%$r_items)) ;
my $rx = qr/($r)/ ;

my %result = () ;

while (my $line = <DATA>) {
  ITEM: while ($line =~ m/$rx/g) {   
    my $value = $1 ;
    $value =~ s/\s*\z// ;
    foreach my $id (keys %$r_items) {
      if ($value =~ m/$r_items->{$id}/) {
        $result{$id} = $1 ;     # Worry about multiple values ?
        next ITEM ;
      } ;
    } ;

    die "Found '$value', but no match ...??" ;
  } ;
} ;

foreach my $id (keys %result) {
  print "$id = '", $result{$id} || '', "'\n" ;
} ;

__DATA__
  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg
LotRecord "Don't Look Back"
  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg
  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg
DeviceID 1 {"The Device"}
  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg
StepID 1 {"Staircase"} Field SlotNumber 1 {497562} DefectList
  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg
WaferRecord "Sandwich"
  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg

Field ResultTimestamp 7 {25-Oct-1952}

Field RecipeID 3 {First catch your rabbit}
Field OrientationMarkLocation 1 {This way up}

  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg
  gjhfgljhgwdchgdjlwhgjhdgsljh sg hjhg sljhg sljhg ljhjlhg sljg
Field DiePitch 3 {Beetle} Field SampleCenterLocation 4 {Gravitas}
ghcgjhcgjhghjgd sljh dsg
;kj sh;kj shkj dhk sjdh
[download]

I can think of ways to improve the inner loop, which is iterating over the item regexes -- but I wouldn't worry about that unless this is still not fast enough.

PS: incidentally, I'd look at the regexes and see if:

• you want to replace single spaces by '\s+', to allow a little lee-way.

• you can replace '.*' and '.+' by '[^?]*' and '[^?]+', where '?' is the expected terminator (eg '"' or '}' etc).

The very rough code above makes a mess of dealing with the Field DiePitch line, because the regex gets greedy !

Others have already suggested ways to speed your search. I'm just going to throw in a technique I occasionally find useful when dealing with large files. Sometimes you can easily differentiate between different types of data in your file, and take a quick pass over the file, discarding the obviously uninteresting stuff, creating a much smaller extract that fits in memory. You can then process that extract. For example, suppose your file looked something like this:

This header section contains a bunch of left-justified
lines that are all shorter than 60 characters. Only the
headers and summary lines are interesting.

  Col1   Col2   Col3  Notes
  ----   ----   ----  -------------
     1    123    123  Foo bar baz
     2    741    200  Barbaz Foobar
     3    100      0  Boofar fazboo
         Total:  323

Next header section, etc.
[download]

So you could discard all unless they are left-justified and shorter than 60 characters or don't contain 'Total:'. You can then use the faster in-memory techniques to dig through the extract. Something like so:

my @extract;
while (<$INF>) {

    # Ignore useless lines
    next if length($_) > 60;
    next unless /^(\w|\s*Total:)/;

    push @extract, $_;
}

# Now you can process @extract for the interesting stuff
print @extract;
[download]

...roboticus

Time flies like an arrow ... fruit flies like a banana.

--Groucho Marx