When using Sybase's "bcp out" to a delimited file, fix the default date format to be something more portable (and sortable). This assumes a pipe delimited file, adding options to change that is left as an exercise. This is a function instead of a standalone script so that it can be included within another program.
BEGIN {
my $pgm = <<'EOT';
my @mon = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
my %mons;
my $i;
$mons{$_} = ++$i for @mon;
my $mon_str = join("|", @mon);
my $mon_re = qr/$mon_str/;

s/(^|\|)($mon_re)\s{1,2}(\d{1,2})\s(\d{4})\s\s?(\d\d?):(\d\d):(\d\d):(
+\d{3})([AP])M(\||$)/
  $1.
  sprintf("%04d-%02d-%02d %02d:%02d:%02d.%03d",
    $4,
    $mons{$2},
    $3,
    ( $9 eq "P" && $5 < 12) ? $5 + 12 : ( $9 eq 'A' && $5 == 12 ) ? 0 
+: $5,
    $6,
    $7,
    $8).
  $10
/eg;
EOT

sub fix_bcp_file {
  my ($file) = @_;
  system($^X, "-pi", "-e", $pgm, $file);
}
}

[download]

Replies are listed 'Best First'.
Re: Sybase BCP date formatter
by jwkrahn (Abbot) on Nov 22, 2008 at 02:29 UTC

    OK, but why run that through system when you can just run it directly in perl: 

    {   my %mons = qw( Jan 1 Feb 2 Mar 3 Apr 4 May 5 Jun 6 Jul 7 Aug 8 Sep
+ 9 Oct 10 Nov 11 Dec 12 );
    my $mon_str = join '|', keys %mons;
    my $mon_re = qr/$mon_str/;

    sub fix_bcp_file {
        my ( $file ) = @_;
        local ( $^I, @ARGV ) = ( '', $file );
        while ( <> ) {
            s/(^|\|)($mon_re)\s{1,2}(\d{1,2})\s(\d{4})\s\s?(\d\d?):(\d
+\d):(\d\d):(\d{3})([AP])M(\||$)/
              $1 .
              sprintf( '%04d-%02d-%02d %02d:%02d:%02d.%03d',
                $4,
                $mons{ $2 },
                $3,
                ( $9 eq 'P' && $5 < 12) ? $5 + 12 : ( $9 eq 'A' && $5 
+== 12 ) ? 0 : $5,
                $6,
                $7,
                $8 ) .
              $10
            /eg;
            print;  # UPDATED thanks runrig
        }
    }
}

    [download]
[reply]
[d/l]
      Being very new to Perl, How is a bcp file called to this script?
[reply]
        It's not a full script, it's just a function to put into other programs. Call the function with the name of the file to "fix".
[reply]

Back to Cool Uses for Perl