Old_Gray_Bear,
I would agree with the caveat that it would likely fail to DWIM in many situations. Assuming way too much about how LanX will use it, the following seems to work:

#!/usr/bin/perl
use strict;
use warnings;

{
    my %seen;

    sub iter {
        my ($beg, $end, $by) = @_;

        my $key = join '*', caller();

        return $seen{$key}->() if $seen{$key};

        my $pos = $beg - $by;

        $seen{$key} = sub {
            $pos += $by;
            if ($pos > $end) {
                delete $seen{$key};
                return;
            } 
            return $pos;
        };

        return $seen{$key}->();

    }
}

while (my $x = iter(1, 10, 1)) {
    print "$x\n";
    while (my $y = iter(1, 10, 1)) {
        print "$x - $y\n";
    }
}
[download]

Update: In some versions of perl (5.8.8 and 5.10.0 reported in the CB), an infinite loop results if you delete the print "$x\n"; line. It seems that unless there is some executable statement between the two while loops, caller reports them as happening on the same line. While I think this is a bug in perl, it also shows why this is not a good solution. Running perl -MO=Deparse doesn't seem to support why perl believes they are on the same line.