Maybe one of these would help.

• Weighted random selection
• Weighted random numbers generator
• Efficiently selecting a random, weighted element

(Super Search is pretty super.)

my $RUNS = 100_000;
my $data = [[a => 0.1], [b => 0.5], [c => 0.4]];

my %count;

foreach (1 .. $RUNS) {
    my $pick;
    my $w = 0;
    rand($w += $$_[1]) < $$_[1] and $pick = $$_[0] for @$data;
    $count{$pick}++;
}
while (my ($k, $v) = each %count) {
    printf "%s: %5.2f%%\n", $k, 100 * $v / $RUNS;
}
__END__
c: 39.88%
a:  9.93%
b: 50.19%
[download]

-log(1 - rand)/$weight
[download]

For one item, you can reduce the code to picking the item where this expression has the lowest value. There's no need to actually sort them all.

Here is code for the reduced problem:

my @matrix = ( [a => 0.1], [b => 0.5], [c => 0.4] );
my $chosen = pick(@matrix);

sub pick {
    my($choice, $threshold);
    foreach(@_) {
        my $rand = -log(1 - rand)/$_->[1];
        if(not defined $threshold or $rand < $threshold) {
            $choice = $_->[0];
            $threshold = $rand;
        }
    }
    return $choice;
}
[download]

use Math::Random::MT qw(rand);
[download]

To demonstrate that it works as advertised, here are the results of a test run of 100_000 draws:

my %picked;
for(1 .. 1E5) {
    $picked{pick(@matrix)}++;
}
use Data::Dumper;
print Dumper \%picked;
[download]

$VAR1 = {
          'c' => 40200,
          'a' => 10042,
          'b' => 49758
        };
[download]

p.s. If there can be any items with weight 0, thus, that should never be picked, you will have to skip them at the top of the loop, because otherwise, the expression will barf (division by zero).

my $h = { 
        a => 0.1,
        b => 0.5,
        c => 0.4,
};

for (1..10000)
{
        $s{rand_key($h)}++;
}

print "output: ".join(" ", %s),"\n";

sub rand_key {
        my $h = shift;
        my $r = rand();
        for (keys %$h)
        {
                $r-=$h->{$_};
                return $_ if($r < 0); 
        }
        return undef;
}
__END__
output: c 4024 a 1017 b 4959
[download]

That has the advantage of just one rand().

Things you have to look out for, though:

• the total weight not being 1.0 (or some other "well known" value).

• any of the weights being very, very much smaller than the other weights -- or anything else that will cause problems with floating point subtraction.

• the final value $r being greater than the weight of the last item (due to rounding).

BTW, I think the comparison should be $r < 0.

One could stick the weight at the end of the list:

use strict ; use warnings ;

my $RUNS   = 100_000 ;
my $data   = [[a => 0.1], [b => 0.5], [c => 0.4], [c => 0]] ;

my %count;

foreach (1 .. $RUNS) {
    my $total_weight = $data->[-1]->[1] ;
    if (!$total_weight) {
      $total_weight += $_->[1] for @$data ;
      $data->[-1]->[1] = $total_weight ;
    } ;

    my $pick;
    my $r = rand($total_weight) ;
    foreach (@$data) { if (($r -= $_->[1]) < 0) { $pick = $_->[0] ; la
+st ; } ; } ;
    $count{$pick}++ ;
} ;

while (my ($k, $v) = each %count) {
    printf "%s: %5.2f%%\n", $k, 100 * $v / $RUNS ;
} ;
__END__
c: 39.89%
a:  9.92%
b: 50.19%
[download]

Noting that we can duplicate the last value in the total weight entry, so in the (unlikely) event of not stopping on the last real entry, the last value will come from the weight entry.

This is, like the other solutions, a linear search along your list of possible values. You can speed this up by putting the popular stuff earlier in the list. If that is still too slow -- you have lots of possible values and you're doing this a lot, you can sub divide the list into groups, and prefix each group with its total weight -- then step along the groups reducing $r as above, and then within the selected group increasing $r.... but only if you really have to !

my %odds = (a => 0.1, b => 0.5, c => 0.4 );

my @dize = map { ($_) x int(100 * $odds{$_}) } keys %odds;

for (1..1000) {
  print $dize[rand @dize], "\n";
}
[download]

I like the simplicity of this, and since the probabilities in my case are certain to add up to 1 (because I normalised them) then a 100-long array might be the simplest way.

I have, however, learned a fair amount from everyone else's replies! Thanks all.