Usually you can configure these monsters to run a program when such a new device is plugged in, and this program can also be a Perl script.

I wrote DBD::WMI for that case. It only works under Windows, because WMI (or rather, WBEM) isn't as widespread elsewhere. I don't have the WMI query handy at the moment, but the links I have in DBD::WMI should point you towards the correct resources.

There is a difference in approach for detecting a cd insertion and a usb drive plugin. The cd would have to be mounted, (unless the situation is a usb cdrom drive getting plugged in). So you need to decide: do you want to look for actual mounts, or just the usb subsystem detecting an additional device, or both? Ubuntu does a good job of detection, maybe you should set it up and check out what it does?

Hm, only some heuristics - very fragile, but maybe they work for you:

Output of mount: a mounted CD/DVD has usually a filetype of iso9660 or udf and an ro attribute. USB sticks, -drives, iPods, etc. are often mounted with the flush attribute and might have filetype vfat (not sure: ntfs, msdos).

pb> mount | perl -ne '@mnt = split /\s+/; print "Stick? $mnt[0] $mnt[2
+]\n" if $mnt[4] =~ /vfat|msdos|ntfs/ && $mnt[5] =~ /flush/;'
Stick? /dev/sdd1 /media/BLUESTICK
Stick? /dev/sde /media/IPOD

pb> mount | perl -ne '@mnt = split /\s+/; print "CD/DVD? $mnt[0] $mnt[
+2]\n" if $mnt[4] =~ /udf|iso\d+/ && $mnt[5] =~ /ro/;'
CD/DVD? /dev/sr0 /media/SOYLENT_GREEN
CD/DVD? /dev/sr1 /media/IX0712
[download]

lsusb -v lists the USB devices currently attached but not necessarily mounted. Check e.g. for attribute bInterfaceClass 8 Mass Storage. Though, you might find empty memory card readers, iPODs, everything that has a filesystem interface...

pb> lsusb -v 2>/dev/null | \
    perl -ne '$dev=$_ if /^Bus/; print $dev if /bInterfaceClass\s+8\D/
+'
Bus 002 Device 006: ID 05ac:1301 Apple Computer, Inc.
Bus 002 Device 006: ID 05ac:1301 Apple Computer, Inc.
Bus 002 Device 005: ID 1307:0163
Bus 002 Device 004: ID 05e3:070e Genesys Logic, Inc.
[download]

sub scan_cddvd {
    # mtab file /etc/mtab
    # cd/dvd signature /dev/sr0
    open(MYINPUTFILE, "</etc/mtab");
    my $cddvd_path = 'not found';
    while(<MYINPUTFILE>){
        my($line) = $_;
        chomp($line);
        if($line =~ m/^\/dev\/sr/){
            print "FOUND CD/DVD\n";
            print $line , "\n";
            #$line =~ /(\/media\/.*)\ /;
            $line =~ /(\/media\/\S+)\s+/;
            my $newline = $1;
            print $newline , "\n";
            while($newline =~ m/\\040/){
                $newline =~ s/\\040/ /;
            }
            print $newline , "\n";
            $cddvd_path = $newline
        }              
    }
    close MYINPUTFILE;
    return $cddvd_path;
}
[download]

Your snipped might work for your PC only and you'll only see the last /dev/sr device - which might not be a CD or DVD at all. The following suggestion is only a tiny improvement:

use strict;

# returns list of CD/DVD mountpoints or empty list
sub scan_cddvd { 
    my @drives   = ();
    my $mtabfile = "/etc/mtab";

    open my $mtfh, "<", $mtabfile or die "cannot open $mtabfile - $!";
    while( <$mtfh> ){
      my ($dev, $mountpoint, $fstype, $options) = split /\s+/;
      next unless $fstype =~ /udf|iso\d+/ && $options =~ /ro\b/; 
      #ro: the /ro/-test above should skip CDRW too
      $mountpoint =~ s/\\(0\d+)/chr(oct($1))/eg;  # resolve oct chars
      push @drives, $mountpoint;
    }
    close $mtfh;

    return @drives;
}

print "o <", join(">\no <", scan_cddvd), ">\n";
[download]

Things to note: uses strict; avoids "not found" as a special failure-indicator; returns list of mountpoints; expands all octal escapes; less HW-dependent (e.g. IDE, SCSI, SATA, ...), e.g. not restricted to /dev/sdb; tries a little harder to find a CD or DVD (iso/udf,ro), uses 3 param open and die; no globs (MYINPUTFILE); implicit use of $_; will fail for derviant mtab-formats; ...