You may want something like this?

use strict;
use warnings;

my $string = "Hello World";
while($string =~/./g){
    print "$&\n";
}
[download]

Or,

use strict;
use warnings;

my $string = "Hello World";
my @string = split(//,$string);
for my $str (@string){
    print "$str\n";
}
[download]

Punitha

According to perldoc perldata (paragraph for $MATCH) I would avoid the use of "$&"; I would capture the pattern and use "$1" instead.

use strict;
use warnings;

my $string = "Hello World";
while($string =~/(.)/g){
    print "$1\n";
}
[download]

But usually I prefer the split() solution.

#!/usr/bin/perl 
use strict;
use warnings;
use Data::Dumper;


my @letters = unpack( "(a)*", 'Hello World' );
print Dumper \@letters;


__END__
Output:$VAR1 = [
          'H',
          'e',
          'l',
          'l',
          'o',
          ' ',
          'W',
          'o',
          'r',
          'l',
          'd'
        ];
[download]

hth,
PooLpi

If you want the output as array, you can use split and unpack, otherwise you can use pattern matching with /g flag in a while loop.
example with unpack & character by character processing


$string="Hello World";
$sum = 0;
foreach $ascval (unpack("C*", $string)) {
    $sum += $ascval;
}
print "sum is $sum\n";
# prints "1052"
[download]

for my $index ( 0 .. length( $string ) - 1 ) {
   my $a = index( $string, $index, 1 );
   #
   # do something 
}
[download]

$string = "Hello World";
print join("\n",split //,$string), "\n";
[download]

But you can see that

split //,$string
[download]

is the black magic.

my $string  = "Hello World";
my $revcopy = reverse $string;

print chop($revcopy) . "\n" for 1 .. length($string);
[download]

while (defined(my $chr = chop $revcopy))
{
    print "$chr\n";
}
[download]