#!/usr/bin/perl
use strict;
use warnings;
use Text::CSV;

my $file = $ARGV[0] or die "Usage: $0 <input_file>";
open(my $fh, '<', $file) or die "Unable to open '$file' for reading: $
+!";

my $csv = Text::CSV->new({sep_char => "\t", binary => 1});
$csv->column_names($csv->getline($fh));
while (my $hr = $csv->getline_hr($fh)) {
    print "Amino acid is: $hr->{SEQ} and Prediction is: $hr->{PRD}\n";
}
[download]

So,

  $csv_line =~ /(\d)\t(\d)\t(\d.d{3})\t(\d.d{3})\(\d.d{3})/
[download]

I couldn't see what the '+' in /SEQ+/ was for. What it will do is match 'SEQ' or 'SEQQ' or 'SEQQQ' etc. Again this is not anchored.

Your first problem is that you are looking for two single letters but using \d in your pattern each time, which means a digit; use a character class of [A-Z] (or [A-Za-z] if you expect lower case as well). Secondly, you are using parentheses to capture your three floating point numbers but you dont seem to be using the captures afterwards. Thirdly, a dot is a regular expression metacharacter matching any character (with caveats, see perlretut and perlre) so you need to escape it to match a literal dot. Fourth, using \t is fine if you are absolutely certain that you will only ever have a single tab as a separator; \s+ for one or more white spaces is more robust. Fifth, /SEQ+/ means an 'S', an 'E' then one or more 'Q's and if the 'SEQ' should be at the beginning of the line the pattern should be anchored with a caret; so /^SEQ.+/ might be better.

You are likely to have far more data lines than header lines so it wil save cpu ticks to put that condition first.

...
if( $csv_line =~ /([A-Z])\s+([A-Z])(?:\s+\d\.\d{3}){3}/ )
{
    ...
}
elsif( $csv_line =~ /^SEQ.+/ )
{
    ...
}
else
{
    # What do you do with a line that matches neither pattern?
}
...
[download]

I hope these points are useful.

Cheers,

JohnGG

/^SEQ.+/ is the same as as /^SEQ./*, and it's nearly equivalent to /^SEQ/. The last option is surely the best of the three in this case.

* — Except in the unlikely case that any of @-/@+/$&/$' are used.

THANK YOU ALL VERY MUCH FOR YOUR COMMENTS! In my ignorance I assumed the '+' could function as a wildcard (ie, read SEQ and everything following it!). Much obliged, InfoSeeker

And in that case, I prefer using split:

my @fields = split /\t/, $tsv_line;

if ( $fields[0] eq 'SEQ' ) {
    print "Header of Predictions\n";
}
elsif ( join("", @fields[0,1]) =~ /^\w\w$/) {
    push @ProteinSeq, $fields[0];
    push @Prediction, $fields[1];
    printf "Amino acid is: %s and Prediction is: %s\n", @fields[0,1];
}
[download]

First of all, your first regex, /SEQ+/, matches: SEQ, SEQQ, SEQQQ, SEQQQQ etc. Is that what you want?

In your second regex, \d matches a digit which are characters 0-9. I think you want \w in order to match the word characters.

if ($csv_line =~ /SEQ/) { # If the line contains 'SEQ' anywhere in it 
+this will be true
    print "header\n";
} elsif ($csv_line =~ /^(\w)\t(\w)\t/) { # This will match a word char
+acter at the beginning of a line followed by a tab, another word char
+acter, and another tab
    print "Amino Acid:$1\nPrediction:$2\n";
}
[download]

Therefore your first reaction should always be to use a well tried and tested module such as Text::CSV to split your data records into fields. Not only will it save you from making obvious and not so obvious errors, once you are used to its interface, it will make for fast and easy programming.

open(FILE,"perlmonks.txt") or die $!;
while(<FILE>){
if(/^\s(\w)\s+(\w)/){
print "$1 ::: $2\n";
}
}
[download]