my %freq = (
    a => 123,
    b => 200,
    c => 700,
    ...
    z => 800,
);

my $sum = 0;
for (split //, $word) {
    $sum += $freq{$_};
}
print "Sum: $sum\n";
[download]

Note that the lookup is case sensitive, so may you need lc or uc to fix that.

See perlintro and perldata.

Use a hash for the table.

my %table = (
   A => 123,
   b => 200,
   ...
);

my $sum = 0;
$sum += $table{$_}
   for split //, $word;
[download]

thank you for your quick response ikegami & moritz

use strict;
use warnings;

my %index = (
    a => 123,
    b => 200,
    c => 700,
);
my $word = "abc";
my $sum = 0;

map { $sum += $index{$_}}  split (//,$word);

print $sum;
[download]

Warning: useless use of map in void context.

Ok, so perl may not be giving that to you, but some of us think it should ;-)

This is the same, but has no return value (well, other than the final $sum, but most of us forget that):

$sum += $index{$_} for split //, $word;
[download]

Though, that said, I would still end up using map:

use List::Util qw(sum)
my $sum = sum map $index{$_}, split //, $word;
[download]

My method has the advantage of reading more like English, and the disadvantage of likely being slower and using more memory. That said, it's always important to me that my code looks more like my design docs than like the underlying machine code, though I have to admit that $sum += $index{$_} is just so idiomatic that my mind sees "sum of $index{$_}" when my eyes see "$sum += $index{$_}". I just had to present it as yet another WTDI.

I would think that map is inappropriate here since you are using it in a void context. foreach makes much more sense, as moritz and ikegami have done.

Update: Tanktalus beat me to it.

And of course, you don't have to split the string into a list:

my $sum = 0;
while ( $word =~ /(.)/g ) {
    $sum += $freq{ $1 };
}
print "Sum: $sum\n";
[download]