One way to do it:

#!/usr/bin/perl

my @list = ('a', '6', '5', '5', '4', '5', '0', 'e');

my $hex = join '', @list;

my $bin = unpack("B*", pack("H*", $hex));  # "101001100101010101000101
+00001110"

my $idx = -1;
my @tuner_list = map {$idx++; $_ ? $idx : ()} reverse split //, $bin;

print "@tuner_list\n";  # 1 2 3 8 10 14 16 18 20 22 25 26 29 31
[download]

Step by step:

my $input = 'a6.55.45.0e';;

my( $hex = $input ) =~  tr[.][]d;; ## Remove dots;;

my $revHex = reverse $hex;;

my $packedInt = pack 'h*', $revHex;;

my @tuners;;
vec( $packedInt, $_, 1 ) and push @tuners, $_ for 0 .. 31;;

print "@tuners";;
1 2 3 8 10 14 16 18 20 22 25 26 29 31
[download]

Or as a compact sub:

sub mask2list { 
    ( my $hex = shift ) =~ tr[.][]d; 
    my $packed = pack 'h*', scalar reverse $hex; 
    map{ vec( $packed, $_, 1 )? $_ : () } 0 .. 31;
}

my @tuners = mask2list( 'a6.55.45.0e' );

print "@tuners";
1 2 3 8 10 14 16 18 20 22 25 26 29 31
[download]

I'm sure that pack and unpack can help you quite a bit, maybe together with vec.

(And it might make it easier if you work with pair of hex characters instead of single characters, because a pair of hex chars is a byte, and that works nicer than a 4 bit nibble for many operations).

Short answer: the hex function will convert your strings into hex numbers.

@numbers = ();
for (@list) {
    push @numbers, hex $_;
}
[download]

Perl has an internal representation of hex numbers, where each term starts with 0x, so your list would be

@list = (0xA, 0x6, 0x5, 0x5, 0x4, 0x5, 0x0, 0xE)

Note that simply concatenating a 0x to the front of your string will not work. As well, I played a bit with pack and unpack, and while in theory you can get similar functionality, I couldn't seem to get my expressions right.

Update:Once you have your values in integer format, you can use the bit shift and mod operators to extract the info you actually care about

my $value = 14;
#Examine 3rd bit from the right
print ($value >> 3) % 2;
[download]