... never going to have periods in them it's trivial.

Even if they do it's not too difficult if you split the reversed string with a limit.

use strict;
use warnings;

my @testStrings = qw{
   abc.1.0.1.0
   bnnn.1.0.1.1
   this.that.1.0.2.0
   dots.a.plenty.here.1.0.2.1
   };

foreach my $testString ( @testStrings )
{
    my( $rest, $digits ) =
       map {
               scalar reverse( $_->[ 4 ] ),
               join q{.}, reverse @$_[ 0 .. 3 ]
           }
       map { [ split m{\.}, $_, 5 ] }
       scalar reverse $testString;
    print qq{$rest -- $digits\n};
}
[download]

The output.

abc -- 1.0.1.0
bnnn -- 1.0.1.1
this.that -- 1.0.2.0
dots.a.plenty.here -- 1.0.2.1
[download]

I hope this is of interest.

Cheers,

JohnGG

Fair enough. :) I'll see your improvement and raise you this:

use strict;
use warnings;

my @testStrings = qw{
   abc.1.0.1.0
   bnnn.1.0.1.1
   this.that.1.0.12.0
   dots.a.plenty.here.1.0.2.1
   };

foreach my $testString ( @testStrings )
{
    my @parts = split m{\.}, (scalar reverse $testString), 5;
    my $rest = scalar reverse $parts[4];
    my $digits = join q{.}, 
        map{ scalar reverse $_ } 
        reverse @parts[0..3];
    print qq{$rest -- $digits\n};
}
[download]

If the digits could also be > 10, yours will reverse them (like the this.that in this example is 12, yours would print 21).

--
meraxes

Good catch with the reversed digits. I'm peeved with myself because I've done a similar thing before and should have remembered. Corrected code.

use strict;
use warnings;

my @testStrings = qw{
   abc.1.0.1.0
   bnnn.1.0.1.1
   this.that.1.0.215.0
   dots.a.plenty.here.1.0.21.1
   };

foreach my $testString ( @testStrings )
{
    my( $rest, $digits ) =
       map {
               scalar reverse( $_->[ 4 ] ),
               join
                  q{.},
                  reverse map { $_ = reverse } @$_[ 0 .. 3 ]
           }
       map { [ split m{\.}, $_, 5 ] }
       scalar reverse $testString;
    print qq{$rest -- $digits\n};
}
[download]

And output.

abc -- 1.0.1.0
bnnn -- 1.0.1.1
this.that -- 1.0.215.0
dots.a.plenty.here -- 1.0.21.1
[download]

Cheers,

JohnGG