Is there a way to initialize local variables (e.g. $k for 'key', and $v for 'value') and then have these loaded into the scope of the called code? e.g. like sort does with "a" and "b".

How do I take a hash reference, and then turn it into a list without an intermediate variable to hold it?

Is there a way to initialize local variables (e.g. $k for 'key', and $v for 'value') and then have these loaded into the scope of the called code? e.g. like sort does with "a" and "b".

Yes and no. Yes, you can set variables in the caller's package (like sort does with $a and $b).

sub hmap(&@) {
   my $cb = shift;

   my $caller = caller();
   my $kgr = do { no strict 'refs'; \*{$caller.'::k'} };
   my $vgr = do { no strict 'refs'; \*{$caller.'::v'} };
   local *$kgr = \my $k;
   local *$vgr = \my $v;

   for (...) {
      $k = ...;
      $v = ...;
      $cb->();
   }
}
[download]

But while $a and $b are exempt from strict, $k and $v aren't. You'd have to use something like

... = hmap { our($k,$v); ... } ...;
[download]

So there isn't really an advantage over using arguments as you are doing now.

... = hmap { my($k,$v)=@_; ... } ...;
[download]

One possible workaround is to use $a and $b instead of $k and $v. That's what List::Util does for reduce.

Another possible workaround is to export $k and $v from the module that provides $hmap. Imported variables are exempt from strict.

package Hash::Map;

use Exporter qw( import );
our @EXPORT = qw( $k $v hmap hgrep );

sub hmap(&@)  { ... }
sub hgrep(&@) { ... }

1;
[download]

I copy and pasted the code sample from above, but it failed to compile. I tried a few things but couldn't get it to work (the error is in the dense part where I don't fully understand the syntactical rules). Offending line seems to be:

snippet:

my %new2 =
hmap { $_[1]{nick} =~ /rbush|fred/
          ? $_[0] => { hmap { $_[0], $_[1] } %{$_[1]} }
          : ()
     } %$h;
[download]

Here's the compilation error:

bash-3.2$ perl hmap_good2.pl
syntax error at hmap_good2.pl line 39, near "] =>"
syntax error at hmap_good2.pl line 40, near ":"
Execution of hmap_good2.pl aborted due to compilation errors.
[download]

Possibly I'm missing something simple? Full script pasted below:

use Data::Dumper;

my $h =
{
    1 =>
    {
        nick => 'rbush',
        phone => '5551212',
        bday => '3/12/1965',
    },

    3 =>
    {
        nick => 'ernest',
        phone => '5553300',
        bday => '3/12/1971',
    },

    5 =>
    {
        nick => 'fred',
        phone => '1112300',
        bday => '5/01/1972',
    },

};

sub hmap (&$)
{
    my $code = shift;
    my @i = %{ shift() };
    my @rv;
    push @rv, $code->(shift @i,shift @i) while @i;
    return { @rv };
}

my %new2 =
    hmap { $_[1]{nick} =~ /rbush|fred/
               ? $_[0] => { hmap { $_[0], $_[1] } %{$_[1]} }
          : ()
} %$h;

print Dumper ($new2), "\n";
[download]

Note that the second version (the hash ref one) has the same compile error, but I could get that to work by surrounding the returned hash in "()", i.e.:

my $new2 =
    hmap { $_[1]{nick} =~ /rbush|fred/
               ? ($_[0] => hmap { $_[0], $_[1] } $_[1])
          : ()
} $h;
[download]

Just a precedence issue. Add parens.

my %new2 =
hmap { $_[1]{nick} =~ /rbush|fred/
          ? ( $_[0] => { hmap { $_[0], $_[1] } %{$_[1]} } )
          : ()
     } %$h;
[download]

my $new2 =
hmap { $_[1]{nick} =~ /rbush|fred/
          ? ( $_[0] => hmap { $_[0], $_[1] } $_[1] )
          : ()
     } $h;
[download]