chomp;
while (length($_) > 80) {
    print substr( $_, 0, 80) . "\n";
    $_ = substr( $_, 80, length($_) - 80);
}
print;
[download]

We can condense that a little bit:

print substr( $_, 0, 80, '')."\n" while length >80;
print;
[download]

I left out the chomp to keep the newline....

Jeroen
"We are not alone"(FZ)

Update: Removed two redundant characters.
2: substr isn't that bad.... see thread below

You might also benchmark a version that's not destructive to the string, which could possibly win for long strings:

print "$1\n" while /\G(.{1,80})/gs;
[download]

The advantage here is that the long string in $_ can remain idle and yet scanned, while the substr version requires constant shifting and shortening. And just to factor out the multiple prints, also try:

print map "$_\n", /\G(.{1,80})/gs;
[download]

-- Randal L. Schwartz, Perl hacker

thanks. much clearer. I was originally looping on (length($_) gt 0) but then the substr expression gave be run-time warnings. looping on (length gt 80) simplifies it.
-allan

Then, you could take the following code (yours):

if ( length($_) > 80 ) {
   chop;
   do {
      print substr( $_, 0, 80 ) . "\n";
      if (length($_) > 80) {
         $_ = substr( $_, 80, length($_) - 80 );
      }
      else {
         $_ = "";
      }
   } while length($_);
}
else {
   print $_;
}
[download]

and replace it with (mine):

while (length($_) > 80) {
   print substr($_, 0, 80) . "\n";
   $_ = substr($_, 80);
}
print $_ ;
[download]

Hope this works for you. I am not sure what you want to do with the email headers, perhaps explain a little more on that topic.

Ciao for now
Zig

$rcvd &&= /^\s/ and next;
$rcvd = /^Received:/ and next;
[download]

sub display_email
{
    my ($fn) = @_;

    print "<center>file <i>$fn</i></center>\n";
    if ( open EMAIL, $fn ) {

        print "<hr width=600><br>\n<pre>";
        $/ = '';
        $header = <EMAIL>;              # slurp entire mail header in
        $header =~ s/\n\s+/ /g;         # merge continuation lines
        foreach $_ ( split "\n", $header ) {
            print "$_\n" unless (
                                /^Message-Id:/
                         ||     /^Content[-\w]*:/
                         ||     /^X-[-\w]*:/
                         ||     /^Status: RO/
                         ||     /^Received:/
                         ||     /^Mime-Version:/ );
        }
        # end of headers, now read and display the body of the email
        $/ = "\n";
        print "\n";
        while( <EMAIL> ) {
            chomp;
            # print lines of the file, line-wrapping at column 80
            while ( length($_) > 80 ) {
                print substr( $_, 0, 80 ), "\n";
                $_ = substr( $_, 80 );
            }
            print "$_\n";
        }
        print "</pre>\n";
        close EMAIL;
    }
}
[download]

while( $_ =  <EMAIL> ) {
    if (        /^Message-Id:/
         ||     /^Content-Type:/
         ||     /^Content-Disposition:/
         ||     /^Content-Transfer/
         ||     /^X-[-\w]*:/
         ||     /^Status: RO/
         ||     /^Mime-Version:/ ) {
        next;
    }
    .
    .
    .
}
[download]

@array=qw (Message-ID:
           Content-Type:
           Content-Disposition:
           and_so_on...
);
LINE: while( $_ =  <EMAIL> ) {
    foreach $header (@array) {
        next LINE if /^$header/;
    }
    .
    .
    .
}
[download]

BrotherAde