If you do not need to preserve the order in which you read the lines of your input for each make/model, then you could stuff all the data into a hash-of-hashes structure. This may be more of a memory hog than you can tolerate, but it certainly is faster on my machine than all those mkdir's and open/closes (I created an input file of 13 million lines):

use strict;
use warnings;

# Read all input into data structure
my %cars;
my $i = 0;  # unique tag for hash keys
while (<>) {
    chomp;
    my ($make, $model, $rest) = split /,/, $_, 3;
    $cars{$make}{$model}{"$rest,$i"}++;
    $i++;
}

# Create each directory once
# Open/close each file once
my $out_dir = "/var/tmp/cars"; #Output directory for
for my $make (keys %cars) {
    my $dir = "$out_dir/$make";
    system "mkdir -p $dir";
    for my $model (keys %{ $cars{$make} }) {
        open my $fh, '>', "$out_dir/$make/$model" or die $!;
        for my $rest (keys %{ $cars{$make}{$model} }) {
            my @specs = split /,/, $rest, 2;
            print $fh (join ',', ($make, $model, @specs)), "\n";
        }
        close $fh;
    }
}
[download]

Update: On second thought, I think you can preserve input order by using an HoHoA instead of the HoHoH above. That should get rid of the smelly tag I introduced, too.