It's impossible to do exactly that, since a sub can only return a list of scalars. The entire list would be assigned to @file.

You could return array references, though.

sub getfile {
   ...
   return ( \@file, \@file2 );
}

my ($file, $file2) = getfile('file.txt', 'file2.txt');

for (@$file ) { ... }
for (@$file2) { ... }
[download]

sub getfile {
    for my $request ( @_ ) {
        @{ $request->{'out'} } = ... $request->{'in'} ...;
    }
}

getfile(
    { 'in' => 'file.txt', 'out' => \@file },
    { 'in' => 'file2.txt', 'out' => \@file2 },
);
[download]

Number of variables passed to function may vary

If each input and each output are independent as they appear, it's a bad design. Use a loop on the outside of the function, not inside.

sub getfile {
   my ($qfn) = @_;
   open(my $fh, '<', $qfn)
      or die("Can't open \"$qfn\": $!\n");
   <$fh>
}

my @files = ('file.txt', 'file2.txt' );

my @file_contents = map { [ getfile($_) ] } @files;
[download]

The contents and the names and the contents are in parallel arrays, so it's still not optimal. Fix:

sub getfile {
   my ($qfn) = @_;
   open(my $fh, '<', $qfn)
      or die("Can't open \"$qfn\": $!\n");
   <$fh>
}

my @files = ('file.txt', 'file2.txt' );

my %file_contents = map { $_ => [ getfile($_) ] } @files;
[download]

You can access the data as follows:

for my $file (keys %file_contents) {
   print("File $file:\n");

   my $content = $file_contents{$file};
   for my $line (@$content) {
      print($line);
   }

   print("\n");
}
[download]