How is this question different than Read two files and print?

As long as there is enough memory in your computer to hold both files in a hash (use the contents of the ID column as the key), it is not "huge".

For any value above that, you are best advised to use a database, such as SQLite for which exists DBD::SQLite.

"Merge" ... "datasets" ... "by (something)". Gee, that sounds like SQL.

  select id, name from fileone where id in (select id from filetwo)
[download]

#! /usr/bin/perl
use strict;
use warnings;

use DBI;

my $dbh = DBI->connect("DBI:CSV:f_dir=.;csv_eol=\n;csv_sep_char=\t");
unlink 'out';
$dbh->do("create table out (id integer, name char(64))");
$dbh->{csv_tables}{f1}{col_names} = [qw(id name)];
$dbh->{csv_tables}{f2}{col_names} = [qw(id)];

my $d = $dbh->selectall_arrayref('select id, name from f1 where id in 
+( select id from f2 )', {});
[download]

my ($File_1_line,$File_2_line);
open(F1,"File_1");
open(F2,"File_2");

while($File_1_line=<F1>)
{
    #chomp $File_1_line;
    my @data=split(' ',$File_1_line);

    seek(F2,0,0);
    while($File_2_line=<F2>)
    {
      chomp $File_2_line;
      print "@data\n" if($data[0] eq $File_2_line);
    }


}
[download]

Try this it will help you.

The first approach could be to load the file that maps IDs and Names in a hash, then read each ID on the second file extracting the associated name

If that fails (because the "index" file is really huge and the hash doesn't fit in memory) you can try to build a database with your index file (DBD::SQLite) or maybe (it depends on your data) you can try with pack and unpack.

If your IDs are numbers and not too sparse and your names are of similar length, you can try something like:

use strict;
use warnings;

my ($file1, $file2) = @ARGV;

my $maxL = 40; # max name length
my $ids = 10000000;  # last id
my $bin="\0" x ($maxL * $ids) ;

# Create the index
open my $fh1, "<", $file1 or die $!; 
while (<$fh1>){
    chomp;
    my ($id,$name) = split /\s+/;
    substr($bin, $id*$maxL, $maxL, pack ("A$maxL",$name));
}
close $fh1;

# Search $ids from file 2
open my $fh2, "<", $file2 or die $!;
while (<$fh2>){
    chomp;
    my $binval = substr ($bin,$_*$maxL,$maxL);
    my $valback = unpack ("A$maxL",$binval);
    print "$_ => $valback\n";
}
close $fh2;
[download]

If this doesn't help you, provide us with a little more information about your input data (type of "IDs" and "Names", number of rows, etc...)