However that said, virtually every line has "room for improvement". Here is a list of specifics:

• Get rid of the () in your function declaration. Prototypes in Perl almost certainly don't do what you think they do, and are likely to cause confusion for maintenance programmers. Consider them and idea that didn't work out and drop them.
• These days instead of saying DIR you can say my $dir and have a private variable. Private variables are good.
• You are passing in the directory to read as a global variable named $logSite. Decades of experience backed up by much research says that using global variables like this is poor practice. Perl has a perfectly good way of passing arguments to functions - use it.
• While you are at it add the directory and the error you got to the error message. You know, like perlstyle tells us to. This makes debugging problems much easier.
• Your use of foreach $pattern (@ARGV) { strongly suggests that you are not using strict.pm. Using that pragma will catch a lot of your bugs immediately, so it is well worth the little bit of declaration effort to make it work properly.
• Again using @uploads without declaring it private means that you are using a global variable with all of the resulting ability to accidentally overwrite global data. It also means that if you call your function twice, you will get bad data.
• If a file matches multiple patterns it will be in your array multiple times. Is that really what you want?
• There is no need to close the directory if you are not checking for errors. (Theoretically checking for errors there is a good idea. I am willing to be sloppy there though because the odds of an error are so low.)
• I would return @uploads rather than \@uploads to reduce potential surprise depending on how it is called.

sub getfiles
{
  my ($dirName, @patterns) = @_;
  opendir(my $dir, $dirName) or die "Can't open '$dirName': $!";
  my @return;
  for my $file (readdir($dir))
  {
    for my $pattern (@ARGV)
    {
      if ($file =~ /$pattern/)
      {
        push @return, $file;
        # This avoids having the file in the result twice
        last;
      }
    }
  }

  return @return;
}
[download]

my @uploads = getfiles($logSite, @ARGV);
[download]

You are returning a reference to the array, not the array itself. That is a fine thing to do, but then you want to dereference it at the receiving end. Something like this:

sub getfiles()
{
  opendir DIR,$logSite or die "Unable to open Directory, please try ag
+ain";
  foreach $pattern (@ARGV)
  {
    push (@uploads, grep /$pattern/, readdir(DIR));
  }
  closedir DIR;
   
  return \@uploads;
}

my $aref = &getfiles;
print @$aref;  # or whatever
[download]

sub getfiles()
{
  opendir DIR,$logSite or die "Unable to open Directory, please try ag
+ain";
  my @uploads;
  foreach $pattern (@ARGV)
  {
    push (@uploads, grep /$pattern/, readdir(DIR));
  }
  closedir DIR;
   
  return \@uploads;
}
[download]

my $uploads = getfiles();

for my $uploaded_file (@$uploads) {
    print "Filename: $uploaded_file\n";
}
[download]

    ...snip...
    return @uploads;
}

my @uploads = getfiles()
[download]

#!/usr/bin/perl 
use strict;
use warnings;  

sub getfiles
{
  my ($logSite) = @_;
  
  my @uploads;
  
  opendir DIR,$logSite or die "Unable to open Directory, please try ag
+ain";
  
  foreach my $pattern (@ARGV)
  {
    push (@uploads, grep /$pattern/, readdir(DIR));
  }
  
  closedir DIR;
   
  return \@uploads;
}

my $ref = getfiles('.');

print "@$ref\n";
[download]

how to I return an array from a funciton?

Perl 5 subroutines return flattened lists.

From the docs (perlsub):

The Perl model for function call and return values is simple: all functions are passed as parameters one single flat list of scalars, and all functions likewise return to their caller one single flat list of scalars.

No, nothing wrong here. It might be better to have a 'my @uploads;' before the loop so that you don't use the global variable, but that shouldn't prevent it from working.

Please post the code where you access the returned array.

my $ref = getfiles();
my @uploads = @$ref;
[download]

return @aref;
[download]