You want to use the -i and -p options. Do a perldoc perlrun for a complete list of Perl options.

Your script should look like:

#!/bin/perl -w -i .bak -p
s/foo/toto/g; 
s/^\s*//;
[download]

This will do the substitution on each line of the file(s) passed as arguments and save the original files with a .bak suffix.

mirod's reply is probably what you want.

If you'd like to do this in a program, set the $^I variable (same thing as -i on the cmd line) to .bak or whatever. Or don't set it, and you'll just write over the file. Make sure @ARGV is set to the file name(s), either via the cmd line or in the program.

  perl -pi '.orig' -e 's/SPONGE/WIBBLE/' FILE
[download]

UPDATE
Could you please try and name your nodes with care. General Perl question will not help someone else looking for the same answer as you. It is a good question but a more carefully worded question would have really increased the value of the node.
--

Zigster

Um I don't think this is being run from the command line, but a script the only flags you can't use in a script IIRC is -M and -m. The script finds all files ending in .bak and processes them.

++ for the node naming chastisement though. ;-)

--

Brother Frankus.

my $filename = 'foo.txt';

open IN, "< $filename" or die "Can't open $filename: $!\n";
open OUT, "> $filename.bak" or die "Can't write to $filename: $!\n";
while (<IN>) {
  s/foo/blah/g;
  print OUT $_;
}
close IN; close OUT;
rename "$filename.bak", $filename;
[download]

The flags work without the command line, too. The following will convert any files specified on the command line to all caps.

#!/usr/bin/perl -w -i.bak -p

$_ = uc;
[download]

In fact, there was an Obfuscated Perl contest entry a while back that does DOS-to-Unix conversions using only command line switches on the shebang line.

xoxo,
Andy

# Andy Lester  http://www.petdance.com  AIM:petdance
%_=split';','.; Perl ;@;st a;m;ker;p;not;o;hac;t;her;y;ju';
print map $_{$_}, split //,
'andy@petdance.com'

What I meant was that my code can be dropped in the middle of a program, while to use the switches in the middle of a program you would have to spawn a new perl with those switches.

#!/usr/bin/perl -w
.....
system(q#perl -i.bak -p -e '$_ = uc'#);
.....
[download]

One element of this that most people foget is that it is possible to make the file smaller with search and replace operations. That means you have to truncate the file length.

Here is my code:

use IO::File qw( &SEEK_SET );
 
my $fh = IO::File->new("+<foo.out")
        or die "failed to open file: $!";
 
while (<$fh>) {
        my $line = $_;
        chomp $line;
 
        $line =~ s/foo/f/g;
 
        push @output, $line;
}
 
my $output = join("\n", @output);
 
$fh->seek( 0 , SEEK_SET );
 
$fh->print($output, "\n");
 
$fh->truncate( length($output) );
 
$fh->close;
 
exit 0;
[download]

TIMTOWTDI: Here is a non-OO way:

use Fcntl qw( &SEEK_SET );

open(FH, "+<foo.out")
  or die "failed to open file";

while (<FH>) {
  my $line = $_;
  chomp $line;

  $line =~ s/foo/f/g;

  push @output, $line;

}

my $output = join("\n", @output);

seek(FH, 0 , SEEK_SET );

print FH $output, "\n";

truncate(FH, length($output) );

close(FH);

exit 0;
[download]